学步园

创建单行 lambda 表达式子例程
在任何可以使用委托类型的情况下，键入关键字 Sub，如下面的示例所示。
Dim add1 = Sub
在紧跟在 Sub 后面的括号中键入子例程的参数。 请注意，不要在 Sub 后面指定名称。 
Dim add1 = Sub (msg As String)
在参数列表后面，键入单个语句作为子例程体。
VB
 
Dim writeMessage = Sub(msg As String) Console.WriteLine(msg)








可以通过传递字符串参数来调用 lambda 表达式。



VB



 



' The following line prints "Hello".
writeMessage("Hello")














创建多行 lambda 表达式函数












在任何可以使用委托类型的情况下，键入关键字 Function，如下面的示例所示。
Dim add1 = Function
在紧跟在 Function 后面的括号中键入函数的参数。 请注意，不要在 Function 后面指定名称。 
Dim add1 = Function (index As Integer)
按 Enter。 将自动添加 End Function 语句。 
在函数体内，添加以下代码以创建表达式并返回值。 不要使用 As 子句指定返回类型。 
VB
 
Dim getSortColumn = Function(index As Integer)
                        Select Case index
                            Case 0
                                Return "FirstName"
                            Case 1
                                Return "LastName"
                            Case 2
                                Return "CompanyName"
                            Case Else
                                Return "LastName"
                        End Select
                    End Function








可以通过传递整数参数来调用 lambda 表达式。



VB



 



Dim sortColumn = getSortColumn(0)











创建多行 lambda 表达式子例程



在任何可以使用委托类型的情况下，键入关键字 Sub，如下面的示例所示：
Dim add1 = Sub


在紧跟在 Sub 后面的括号中键入子例程的参数。 请注意，不要在 Sub 后面指定名称。 
Dim add1 = Sub(msg As String)


按 Enter。 将自动添加 End Sub 语句。 


在函数体内，添加以下代码以在调用子例程时执行。



VB



 



Dim writeToLog = Sub(msg As String)
                     Dim log As New EventLog()
                     log.Source = "Application"
                     log.WriteEntry(msg)
                     log.Close()
                 End Sub








可以通过传递字符串参数来调用 lambda 表达式。



VB



 



writeToLog("Application started.")















lambda 表达式的一个常见用途是定义一个函数，该函数可作为 Delegate 类型的形参的实参进行传递。 在下面的示例中，GetProcesses 方法返回在本地计算机上运行的进程的数组。 Enumerable 类中的 Where 方法需要使用一个 Boolean 委托作为参数。 该示例中的 lambda 表达式就是为此目的而使用的。 对于每个仅有一个线程的进程以及在 filteredList 中选择的进程，它将返回 True。 
VB 
Sub Main()

    ' Create an array of running processes.
    Dim procList As Process() = Diagnostics.Process.GetProcesses

    ' Return the processes that have one thread. Notice that the type
    ' of the parameter does not have to be explicitly stated.
    Dim filteredList = procList.Where(Function(p) p.Threads.Count = 1)

    ' Display the name of each selected process.
    For Each proc In filteredList
        MsgBox(proc.ProcessName)
    Next

End Sub








上一个示例等效于下面用语言集成查询 (LINQ) 语法编写的代码： 



VB 




Sub Main()

    Dim filteredQuery = From proc In Diagnostics.Process.GetProcesses
                        Where proc.Threads.Count = 1
                        Select proc

    For Each proc In filteredQuery
        MsgBox(proc.ProcessName)
    Next
End Sub