现在的位置: 首页 > 综合 > 正文

S3C2440启动代码详细注释

2018年04月11日 ⁄ 综合 ⁄ 共 38555字 ⁄ 字号 小 中 大 ⁄ 评论关闭

功能:作为C程序启动代码,配置内存、中断向量、栈,初始化C语言环境变量  


大概流程：     

1.定义处理器模式及各模式的堆栈指针常量用于初始化堆栈sp(R13)

2.设置处理器模式

3.宏定义MOV_PC_LR，作用：子程序返回

4.第一次查表实现中断向量的重定向

5.代码入口

6.大小端判断与转换

7.中断的第二次查表

8.禁止看门狗,屏蔽所有中断

9.设置系统时钟频率

10.初始化内存控制器


[php] view plaincopyprint?

  1. ;================================================================  
  2. ; NAME: 2440INIT.S  
  3. ; DESC: C start up codes  
  4. ;       Configure memory, ISR ,stacks  
  5. ;   Initialize C-variables  
  6. ; HISTORY:  
  7. ; 2002.02.25:kwtark: ver 0.0  
  8. ; 2002.03.20:purnnamu: Add some functions for testing STOP,Sleep mode  
  9. ; 2003.03.14:DonGo: Modified for 2440.  
  10. ; 2009 06.24:Tinko Modified  
  11. ;================================================================  
  12.   
  13. ;================================================================  
  14. ;GET和INCLUDE的功能是相同的，功能都是引进一些编译过的文件  
  15. ;汇编不能使用include包含头文件，所以用Get  
  16. ;汇编也不认识*.h 文件，所有只能用*.inc  
  17. ;================================================================  
  18.     GET option.inc  ;定义芯片相关的配置,包含选项说明，如pll等    
  19.     GET memcfg.inc  ;定义存储器配置,包含MMU配置说明     
  20.     GET 2440addr.inc ;定义了寄存器符号,包含各寄存器地址说明  
  21.   
  22. ;================================================================     
  23. ;定义SDRAM工作在Reflesh模式下，SDRAM有两种刷新模式：selfreflesh,autoreflesh。  
  24. ;后者是在其使用过程当中设置的。  
  25. ;REFRESH寄存器[22]bit : 0- auto refresh; 1 - self refresh    
  26. ; MMU自刷新  
  27. ; EQU相当于C语言中的#define  
  28. ;================================================================  
  29. BIT_SELFREFRESH EQU (1<<22)   ;用于节电模式中，SDRAM自动刷新  
  30.   
  31. ;处理器模式常量: CPSR寄存器的后5位决定目前处理器模式 M[4:0]  
  32. ;Pre-defined constants ;系统的工作模式设定  
  33. USERMODE    EQU     0x10 ;用户模式  
  34. FIQMODE     EQU     0x11 ;快速中断模式  
  35. IRQMODE     EQU     0x12 ;中断模式  
  36. SVCMODE     EQU     0x13 ;监管模式  
  37. ABORTMODE   EQU     0x17 ;异常中断模式  
  38. UNDEFMODE   EQU     0x1b ;未定义模式  
  39. MODEMASK    EQU     0x1f ;模式掩码  
  40. NOINT       EQU     0xc0 ;取消中断  
  41.   
  42. ;================================================================  
  43. ;定义各模式的堆栈指针常量用于初始化堆栈sp(R13)  
  44. ;用于下面对各个模式中堆栈的设置  
  45. ;如何确保堆栈不会溢出?  
  46. ;在ADS环境下ARM堆栈为只能为递减堆栈(SP向低地址方向伸张)  
  47. ;堆栈参考:http://apps.hi.baidu.com/share/detail/5538633  
  48.   
  49. ;The location of stacks ;定义处理器各模式下堆栈地址常量  
  50. ;在option.inc中定义了_STACK_BASEADDRESS EQU 0x33ff8000  
  51. ;================================================================  
  52. UserStack   EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~  
  53. SVCStack    EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~  
  54. UndefStack  EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~  
  55. AbortStack  EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~  
  56. IRQStack    EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~  
  57. FIQStack    EQU (_STACK_BASEADDRESS-0x0)    ;0x33ff8000 ~  
  58.   
  59. ;================================================================  
  60. ;检查在tasm.exe里是否设置了采用THUMB(16位)代码(armasm -16 ...@ADS 1.0)  
  61. ;判断是不是thumb指令。  
  62. ;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.  
  63. ;{CONFIG}编译器内建变量具体参考手册  
  64. ;================================================================  
  65.     GBLL    THUMBCODE   ;定义THUMBCODE全局变量(逻辑型)  
  66.     [ {CONFIG} = 16     ;如果发现是用16位代码的话  
  67. THUMBCODE SETL  {TRUE}  ;把THUMBCODE设置为TURE  
  68.         CODE32  
  69.         |               ;否则是ARM模式  
  70. THUMBCODE SETL  {FALSE}  
  71.     ]  
  72.   
  73. ;宏定义MOV_PC_LR，作用：子程序返回  
  74. ;寄存器R14又被称为连接寄存器（LR），在ARM中有下面两种特殊用途。  
  75. ;每一种处理器模式在自己的物理R14中存放当前子程序的返回地址。  
  76. ;当通过BL或者BLX指令调用子程序时，R14被设置成该子程序的返回地址。  
  77. ;在子程序中，当把R14的值复制到程序计数器PC中时，就实现了子程序返回  
  78. ;详见http://blog.csdn.net/liufei_learning/archive/2010/08/22/5830374.aspx  
  79.   
  80.         MACRO       ;宏定义  
  81.     MOV_PC_LR  
  82.         [ THUMBCODE     ;在目标地址是THUMB指令,在ARM模式中  
  83.         bx lr           ;要用BX指令转THUMB 使跳到THUMB指令,并转换模式，BX会根据PC的最后一位判断是否进入thumb模式  
  84.         |  
  85.         mov pc,lr       ;否则，就是目标地址是ARM模式，就直接把函数返回地址赋给PC  
  86.         ]  
  87.     MEND  
  88.       
  89. ;宏定义MOVEQ_PC_LR，作用：带相等条件判断的子程序返回 。与宏定义  
  90. ;MOV_PC_LR类似  
  91.         MACRO  
  92.     MOVEQ_PC_LR  
  93.         [ THUMBCODE  
  94.         bxeq lr  
  95.         |  
  96.         moveq pc,lr  
  97.         ]  
  98.     MEND    ;宏定义结束  
  99.   
  100. ;===============================================================  
  101. ;下面这个宏是用于第一次查表过程的实现中断向量的重定向,你会发现  
  102. ;在_ISR_STARTADDRESS=0x33FF_FF00里定义的第一级中断向量表  
  103. ;是采用型如Handle***的方式的. 而在程序的ENTRY处(程序开始处)采用的是  
  104. ;b Handler***的方式.  
  105. ;在这里Handler***就是通过HANDLER这个宏和Handle***进立联系的.  
  106. ;这种方式的优点就是正真定义的向量数据在内存空间里,而不是在ENTRY处  
  107. ;的ROM(FLASH)空间里, 这样,我们就可以在程序里灵活的改动向量的数据了.  
  108. ;其中HANDLER是一个宏，用于查找中断处理程序的入口地址。这些地址存放在  
  109. ;由HandleXXX指向的表项中，该表定位在RAM高端，基地址为_ISR_STARTADDRESS。  
  110. ;假如_ISR_STARTADDRESS为 0x800000000,当IRQ中断时,根据b HandlerFIQ,先跳转  
  111. ;再根据^ _ISR_STARTADDRESS基地址+HandleIRQ 的偏移地址(4*6)得到的中断地址  
  112. ;0x80000000+0x00000024=0x80000024  
  113. ;==========================================================================================  
  114.   
  115. ;===============================================================================================================  
  116. ;注意下面这段程序是个宏定义  
  117. ;下面包含的HandlerXXX  HANDLER  HandleXXX将都被下面这段程序展开  
  118. ;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。  
  119. ;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字，即4字节  
  120. ;空间都有一个标号，以Handle***命名。  
  121. ;在向量中断模式下使用“加载程序”来执行中断服务程序。  
  122. ;这里就必须讲一下向量中断模式和非向量中断模式的概念  
  123. ;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的指令取代0x18处的指令，  
  124. ;通过跳转指令系统就直接跳转到对应地址  
  125. ;函数中 节省了中断处理时间提高了中断处理速度标 例如ADC中断的向量地址为0xC0,则在0xC0处放如下代码：  
  126. ;ldr PC,=HandlerADC 当ADC中断产生的时候系统会自动跳转到HandlerADC函数中  
  127. ;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt pending寄存器中对应标志位置位  
  128. ;然后跳转到位于0x18处的统一中断;函数中  
  129. ;该函数通过读取interrupt pending寄存器中对应标志位来判断中断源，并根据优先级关系再跳到;对应中断源的处理代码中  
  130. ;大致作用是把宏的第一个参数$HandlerLabel转变为一个标号，然后让程序跳转到第二个参数$HandleLabel(为一个地址)  
  131. ;对应的值的地址去。  
  132.   
  133. ;==================================================================================================================  
  134. ;SP 堆栈指针，指向当前堆栈地址  
  135. ;MACRO  
  136. ;下面一句一句分析一下，为了便于分析，假设sp = 0x33ff8000，$HandleLabel = 0x33ffff00,  
  137. ;[0x33ffff00]=0x10000000，r0 =0x56001234：  
  138. ;$HandlerLabel HANDLER $HandleLabel  
  139. ;宏的名字叫HANDLER ,有两个参数  
  140. ;$HandlerLabel    定义一个标号  
  141. ;      sub  sp,sp,#4   ;decrement sp(to store jump address)  
  142. ;把栈顶指针减4，留出一个字的空间（用于保存跳转地址的值）,sp=0x33ff7ffc  
  143. ;       stmfd      sp!,{r0}  ;PUSH the work register to stack(lr does not push because it return to original address)  
  144. ;首先把sp减4 (sp=0x33ff7ff8)，然后把将要使用的r0寄存器入栈，此时[0x33ff7ff8]=0x56001234  
  145. ;       ldr     r0,=$HandleLabel;load the address of HandleXXX to r0  
  146. ;给寄存器r0赋值，r0=0x33ffff00  
  147. ;       ldr     r0,[r0]      ;load the contents(service routine start address) of HandleXXX  
  148. ;给寄存器r0赋值，r0=0x10000000  
  149. ;       str     r0,[sp,#4]      ;store the contents(ISR) of HandleXXX to stack  
  150. ;把寄存器r0保存到0x33ff7ffc (0x33ff7ff8+4)，sp没有改变sp=0x33ff7ff8,如果  
  151. ;str     r0,[sp,#4]！sp 改变  
  152. ;此时  
  153. ;[0x33ff7ffc] = 0x10000000  
  154. ;       ldmfd   sp!,{r0,pc}     ;POP the work register and pc(jump to ISR)  
  155. ;把栈顶的两个字弹出，分别保存到r0、pc，此时sp=0x33ff8000，r0=0x56001234，pc=0x10000000，  
  156. ;通过比较不难发现，sp和r0在执行前后都没有变化，程序就跳转到0x10000000处执行  
  157. ;       MEND  
  158. ;所以，通过上面的分析可以看出，$HandlerLabel HANDLER $HandleLabel是让PC跳转到$HandleLabel中存放的地址执行。  
  159. ;==================================================================================================================  
  160.         MACRO  
  161. $HandlerLabel HANDLER $HandleLabel  
  162.   
  163. $HandlerLabel  
  164.     sub sp,sp,#4    ;decrement sp(to store jump address) ;减少sp(用于存放转跳地址)实质上是在计算返回地址  
  165.     stmfd   sp!,{r0}    ;PUSH the work register to stack(lr does not push because it return to original address)  
  166.     ldr     r0,=$HandleLabel;load the address of HandleXXX to r0 ;将HandleXXX的址址放入r0  
  167.     ldr     r0,[r0]  ;load the contents(service routine start address) of HandleXXX   
  168.                      ;把HandleXXX所指向的内容(也就是中断程序的入口)放入r0         
  169.     str     r0,[sp,#4]      ;store the contents(ISR) of HandleXXX to stack ;把中断服务程序(ISR)压入栈.  
  170.     ldmfd   sp!,{r0,pc}     ;POP the work register and pc(jump to ISR)   
  171.                             ;用出栈的方式恢复r0的原值和为pc设定新值(完成了到ISR的转跳)  
  172.     MEND  
  173.   
  174. ;==========================================================================================  
  175. ;一个ARM由RO,RW,ZI三个段组成，其中RO(只读)为代码段，RW(读写)是已经初始化的全局变量，  
  176. ;ZI是未初始化的全局变量  
  177. ;对应于GNU工具的概念是TEXT，DATA，BSS  
  178.   
  179. ;bootloader要将RW段复制到RAM中，并将ZI段清零 编译器使用下列方式来记录各段的起始和结束地址  
  180. ;在这里用IMPORT伪指令(和c语言的extren一样)引入|Image$RO$Base|,  
  181. ;|Image$RO$Limit|...等比较古怪的变量是编译器生成的。  
  182. ;RO, RW, ZI这三个段都保存在Flash中，但RW，ZI在Flash中  
  183. ;的地址肯定不是程序运行时变量所存储的位置，因此我们的程序在初始化时应该  
  184. ;把Flash中的RW，ZI拷贝到RAM的对应位置。这些变量是通过ADS的工程设置里面  
  185. ;设定的RO Base和RW Base设定的, 最终由编译脚本和连接程序导入程序.  
  186. ;实际上RW，ZI在Flash中的位置就紧接着RO存储。我们知道Image$RO$Base，  
  187. ;Image$RO$Limit， 那么Image$RO$Limit就是RW（ROM data）的开始。  
  188. ;============================================================================================  
  189.     IMPORT  |Image$RO$Base| ; Base of ROM code  ;ROM code(也就是代码)的开始地址  
  190.     IMPORT  |Image$RO$Limit|  ; End of ROM code (=start of ROM data) ;ROM code的结束地址(=ROM data的开始地址)       
  191.     IMPORT  |Image$RW$Base|   ; Base of RAM to initialise  ;RAM 的起始地址  
  192.     IMPORT  |Image$ZI$Base|   ; Base and limit of area  ;0初始化的起始地址  
  193.     IMPORT  |Image$ZI$Limit|  ; to zero initialise      ;0初始化的结束地址  
  194.   
  195. ;===============================================================  
  196. ;在这里用IMPORT伪指令(和c语言的extren一样)引入外部变量MMU的快速总线  
  197. ;模式和异步总线模式两个变量  
  198. ;===============================================================  
  199.     IMPORT  MMU_SetAsyncBusMode  ;MMU的快速总线模式  
  200.     IMPORT  MMU_SetFastBusMode  ;异步总线模式  
  201.   
  202. ;这里引入一些在其它文件中实现在函数,包括为我们所熟知的main函数  
  203.     IMPORT  Main        ; The main entry of mon program  
  204.     IMPORT  RdNF2SDRAM  ; Copy Image from Nand Flash to SDRAM ;把镜像从Nandflash拷贝到SDRAM的函数  
  205.   
  206. ;==============================================================================================  
  207. ;初始化程序中必须指明入口地址，因为处理器复位（仿真时，装载image）后PC 要找到入口开始执行代码，  
  208. ;当各种异常或是中断产生的时候也要找到各个异常的入口开始执行代码。  
  209. ;从这里开始就是真正的代码入口了！  
  210.   
  211. ;AREA 伪指令用于定义一个代码段或数据段.ARM 汇编程序设计采用分段式设计,一  
  212. ;个 ARM 源程序至少需要一个代码段,大的程序可以包含多少个代码段及数据段.  
  213. ;CODE   为定义代码段.默认属性为 READONLY；  
  214. ;READONLY  指定本段为只读,代码段的默认属性为READONLY；  
  215.   
  216. ;板子上电和复位后程序开始从位于0x0处开始执行，硬件刚刚上电复位后程序从这里开始执行跳转到标为ResetHandler处执行  
  217. ;DCD用于分配一段字内存单片，并用后面的伪指令初始化，分配字节由expr 个数决定  
  218. ;============================================================================================  
  219.   
  220.     AREA    Init,CODE,READONLY  
  221.   
  222.     ENTRY   ;定义程序的入口(调试用)  
  223. ;ENTRY只是定义一个普通的入口点，且在程序中可以多处定义，如果要使用它作为整  
  224. ;个映像文件的唯一入口点，还需要设置链接器中的相关选项。  
  225.   
  226.     EXPORT  __ENTRY  ;导出__ENTRY，即导出代码段入口地址  
  227. __ENTRY  
  228. ResetEntry  ;复位后入口  
  229.     ;1)The code, which converts to Big-endian, should be in little endian code.  
  230.     ;2)The following little endian code will be compiled in Big-Endian mode.  
  231.     ;  The code byte order should be changed as the memory bus width.  
  232.     ;3)The pseudo instruction,DCD can not be used here because the linker generates error.  
  233.   
  234. ;***********************************************************  
  235. ;1、ASSERT :DEF:ENDIAN_CHANGE  
  236. ;ASSERT 是断言伪指令,语法是:ASSERT +逻辑表达式  
  237. ;def 是逻辑伪操作符，格式为： :DEF:label，作用是：判断label是否定义过  
  238. ;2、下面的四句指令能且只能执行一句，并且前三句若执行跳转后处理程序的最后一句也是  
  239. ;b ResetHandler  
  240. ;3、" [ " 相当于 if  
  241. ;" | "相当于else  
  242. ;" ] " 相当于endif  
  243. ;***************************************************************  
  244.   
  245. ;=================================================================================================================  
  246. ;在0x0处的异常中断是复位异常中断，是上电后执行的第一条指令  
  247. ;变量ENDIAN_CHANGE用于标记是否要从小端模式改变为大端模式，因为编译器初始模式是小端模式，  
  248. ;如果要用大端模式，就要事先把该变量设置为TRUE，否则为FLASE  
  249. ;变量ENTRY_BUS_WIDTH用于设置总线的宽度，因为用16位和8位宽度来表示32位数据时，在大端模式下，数据的含义是不同的  
  250. ;由于要考虑到大端和小端模式，以及总线的宽度，因此该处看似较复杂，其实只是一条跳转指令：  
  251. ;当为大端模式时，跳转到ChangeBigEndian函数处，否则跳转到ResetHandler函数处  
  252. ;=================================================================================================================  
  253.   
  254.     ASSERT  :DEF:ENDIAN_CHANGE ;判断是否定义了ENDIAN_CHANGE,如果没有定义，则报告该处错误信息  
  255.     [ ENDIAN_CHANGE  ;if ENDIAN_CHANGE ==TRUE  
  256.         ASSERT  :DEF:ENTRY_BUS_WIDTH  ;判断是否定义了ENTRY_BUS_WIDTH,如果没有定义，则报告该处错误信息  
  257.         [ ENTRY_BUS_WIDTH=32   if ENTRY_BUS_WIDTH ==32  
  258.         ;跳转到ChangeBigEndian（ChangeBigEndian在0x24），因此该条指令的机器码为0xea000007  
  259.         ;所以该语句与在该处（即0x0处）直接放入0xea000007数据（即DCD 0xea000007）作用相同  
  260.             b   ChangeBigEndian     ;DCD 0xea000007  
  261.         ]   ;跳转到ChangeBigEndian，执行DCD 0xea000007 改变大小端数据模式  
  262.   
  263.         [ ENTRY_BUS_WIDTH=16 ;if ENTRY_BUS_WIDTH ==16     
  264.         ;在小端模式下，用16位或8位数据总线宽度表示32位数据，与用32位总线宽度表示32位数据，格式完全一致。  
  265.         ;但在大端模式下，格式就会发生变化  
  266.         ;在复位时，系统默认的是小端模式，所以就要人为地改变数据格式，使得用16位大端数据表示的32位数据  
  267.         ;也能被小端模式的系统识别  
  268.         ;该语句的目的也是跳转到ChangeBigEndian，即机器码也应该是0xea000007，但为了让小端模式系统识别，  
  269.         ;就要把机器码的顺序做一下调整，改为0x0007ea00，那么我们就可以用DCD 0x0007ea00把机器码装载进去了  
  270.         ;，但由于该处不能使用DCD伪指令，因此我们就要用一条真实的指令来代替DCD 0x0007ea00，  
  271.         ;即该指令编译后的机器码也为0x0007ea00，而andeq  r14,r7,r0,lsl #20就是一条编译后机器码  
  272.         ;为0x0007ea00的指令，所以我们在该处写上该条指令总线的宽度，因此该处看似较复杂，其实只是  
  273.         ;一条跳转指令：当为大端模式时，跳转到ChangeBigEndian函数处，否则跳转到ResetHandler函数处  
  274.             andeq   r14,r7,r0,lsl #20   ;DCD 0x0007ea00  
  275.         ] ;当标志状态寄存器CPSR的Z位=1时,r14=r7+r0逻辑左移20位，执行DCD 0x0007ea00改变大小端模式  
  276.   
  277.         [ ENTRY_BUS_WIDTH=8  ;if ENTRY_BUS_WIDTH ==8  
  278.         ;该语句的分析与上一段代码的分析相似;  
  279.         ;streq  r0,[r0,-r10,ror #1]编译后的机器码为0x070000ea  
  280.             streq   r0,[r0,-r10,ror #1] ;DCD 0x070000ea  
  281.         ] ; 当标志状态寄存器CPSR的Z位=1时…，执行DCD 0x070000ea 改变大小端模式  
  282.         |    ;ELSE 即如果没定义ENDIAN_CHANGE            
  283.         b   ResetHandler  ;复位异常，开发板上电或复位时进入0x00  
  284.     ]  
  285.     b   HandlerUndef    ;handler for Undefined mode 未定义异常，遇到无法识别的指令时0x04  
  286.     b   HandlerSWI  ;handler for SWI interrupt  软中断异常0x08   
  287.     b   HandlerPabort   ;handler for PAbort 指令预取错误时进入0x0c  处理终止程序访问终止模式  
  288.     b   HandlerDabort   ;handler for DAbort 数据访问不能完成时进入0x10  处理数据访问终止模式  
  289.     b   .       ;reserved ； 保留 0x14  "."代表指令的地址 ，即表示进行死循环  
  290.     b   HandlerIRQ  ;handler for IRQ interrupt 发生IRQ 中断时进入0x18  
  291.     b   HandlerFIQ  ;handler for FIQ interrupt 发生FIQ 中断时进入0x1c  
  292.   
  293. ;@0x20  "@" 存储区位置计数器的当前值  
  294.     b   EnterPWDN   ; Must be @0x20.      
  295. ;===============================================================  
  296. ;DCD用于分配一段字内存单元,并用伪指令中的expr初始化.DCD伪指令分配的内存  
  297. ;需要字对齐,一般可用来定义数据表格或其它常数.&与DCD 同义.  
  298. ;下面是改变大小端的程序,这里采用直接定义机器码的方式,至说为什么这么做  
  299. ;就得问三星了反正我们程序里这段代码也不会去执行,不用去管它  
  300. ;===============================================================  
  301. ;由0x0跳转至此，目的是把小端模式改为大端模式，即把CP15中的寄存器C1中的第7位置1  
  302. ChangeBigEndian ;改变大小端数据模式  
  303. ;@0x24  
  304.     [ ENTRY_BUS_WIDTH=32 ;if ENTRY_BUS_WIDTH == 32  
  305.         ;执行mrc p15,0,r0,c1,c0,0，得到CP15中的寄存器C1，放入r0中  
  306.         ;由于mrc p15,0,r0,c1,c0,0的机器码为0xee110f10  
  307.         ;因此DCD 0xee110f10的意思就是mrc p15,0,r0,c1,c0,0。下同  
  308.         DCD 0xee110f10  ;0xee110f10 => mrc p15,0,r0,c1,c0,0    
  309.         ;执行orr r0,r0,#0x80，置r0中的第7位为1，表示选择大端模式  
  310.         DCD 0xe3800080  ;0xe3800080 => orr r0,r0,#0x80;  //Big-endian  
  311.         ;执行mcr p15,0,r0,c1,c0,0，把r0写入CP15中的寄存器C1  
  312.         DCD 0xee010f10  ;0xee010f10 => mcr p15,0,r0,c1,c0,0  
  313.     ]  
  314.     [ ENTRY_BUS_WIDTH=16  ;if ENTRY_BUS_WIDTH == 16  
  315.         ;由于此时系统还不能识别16位或8位大端模式下表示的32为数据  
  316.         ;因此还需人为地进行数据调整，即把0xee110f10变为0x0f10ee11  
  317.         ;然后用DCD指令存入该数据。下同  
  318.         DCD 0x0f10ee11  
  319.         DCD 0x0080e380  ;DCD伪指令定义一个32位存储单元，并初始化  
  320.         DCD 0x0f10ee01  
  321.     ]  
  322.     [ ENTRY_BUS_WIDTH=8 ;if ENTRY_BUS_WIDTH == 8  
  323.         DCD 0x100f11ee  
  324.         DCD 0x800080e3  
  325.         DCD 0x100f01ee  
  326.     ]  
  327.     ;相当于NOP指令  
  328.     ;作用是等待系统从小端模式向大端模式转换  
  329.     ;此后系统就能够自动识别出不同总线宽度下的大端模式，因此以后就无需再人为调整指令了  
  330.     DCD 0xffffffff  ;swinv 0xffffff is similar with NOP and run well in both endian mode.  
  331.     DCD 0xffffffff  
  332.     DCD 0xffffffff  
  333.     DCD 0xffffffff  
  334.     DCD 0xffffffff  
  335.     b ResetHandler  
  336.   
  337. ;当系统进入异常中断后，由存放在0x0~0x1C处的中断向量地址中的跳转指令，  
  338. ;跳转到此处相应的位置，并由事先定义好的宏定义再次跳转到相应的中断服务程序中  
  339. ;如第70行所说,这里采用HANDLER宏去建立Hander***和Handle***之间的联系  
  340. HandlerFIQ  HANDLER HandleFIQ  
  341. HandlerIRQ  HANDLER HandleIRQ  
  342. HandlerUndef    HANDLER HandleUndef  
  343. HandlerSWI  HANDLER HandleSWI  
  344. HandlerDabort   HANDLER HandleDabort  
  345. HandlerPabort   HANDLER HandlePabort  
  346. ;==========================================================================================  
  347. ;这一段程序就是用来进行第二次查表的过程了.如果说第一次查表是由硬件来  
  348. ;完成的,那这一次查表就是由软件来实现的了. 为什么要查两次表??  
  349. ;没有办法,ARM把所有的中断都归纳成一个IRQ中断异常和一个FIRQ中断异常,第一  
  350. ;次查表主要是查出是什么异常,可我们总要知道是这个中断异常中的什么中断呀!  
  351. ;没办法了,再查一次表呗!   
  352. ;==========================================================================================  
  353. ;下面这段代码是用于处理非向量中断，即由软件程序来判断到底发生了哪种中断，  
  354. ;然后跳转到相应地中断服务程序中  
  355. ;具体地说就是，当发生中断时，会置INTOFFSET寄存器相应的位为1，然后通过查表  
  356. ;（见该程序末端部分的中断向量表），找到相对应的中断入口地址  
  357. ;观察中断向量表，会发现它与INTOFFSET寄存器中的中断源正好相对应，即向量表的  
  358. ;顺序与INTOFFSET寄存器中的中断源的由小到大的顺序一致，因此我们可以用基址加  
  359. ;变址的方式很容易找到相对应的中断入口地址。其中基址为向量表的首个中断源地址，  
  360. ;变址为INTOFFSET寄存器的值乘以4（因为系统是用4个字节单元来存放一个中断向量  
  361. ;==========================================================================================  
  362. IsrIRQ  
  363.     sub sp,sp,#4       ; 给PC寄存器保留;reserved for PC  
  364.     stmfd   sp!,{r8-r9} ; 把r8-r9压入栈  
  365.                             ;INTOFFSET的值在2440addr.inc中定义为0x4a000014  
  366.     ldr r9,=INTOFFSET       ; 把中断偏移INTOFFSET的地址装入r9  
  367.     ldr r9,[r9]             ; 把中断偏移INTOFFSET的值装入r9  
  368.     ldr r8,=HandleEINT0     ; 这就是向量表的入口HandleEINT0装入r8  
  369.     add r8,r8,r9,lsl #2     ;R8=R8+(R9<<2)  
  370.     ldr r8,[r8]             ; 装入中断服务程序的入口  
  371.     str r8,[sp,#8]          ;把入口压入堆栈  
  372.     ldmfd   sp!,{r8-r9,pc}  ;出栈  
  373.   
  374. ;LTORG用于声明一个文字池,在使用LDR伪指令时,要在适当的地址加入LTORG声明  
  375. ;文字池,这样就会把要加载的数据保存在文字池内,再用 ARM 的加载指令读出数据.(若  
  376. ;没有使用 LTORG 声明文字池,则汇编器会在程序末尾自动声明.)  
  377. ;定义一个数据缓冲池，供ldr伪指令使用  
  378.     LTORG   ;声明文字池  
  379.   
  380. ;=======  
  381. ; ENTRY  
  382. ;1.禁止看门狗 屏蔽所有中断  
  383. ;=======  
  384. ResetHandler  
  385.     ldr r0,=WTCON       ;watch dog disable  ;关闭看门狗  
  386.     ldr r1,=0x0  
  387.     str r1,[r0]         ;r1->[r0]  禁止看门狗  
  388. ;WTCON 为看门狗控制寄存器，此处将其写入0x0，就是禁止它的所有功能，包括定时器定时，溢出中断及溢出复位。  
  389.   
  390. ;INTMSK 为中断屏蔽寄存器，写入0xffffffff，就是禁止所有的中断产生，因为中断  
  391. ;向量表还未初始化，如果此时产生中断会使程序进入未知的状态而跑飞。因为外设的中断太  
  392. ;多，INTMSK 不够用，还需要INTSUBMSK 来将剩余的中断源也禁止掉。  
  393.     ldr r0,=INTMSK  
  394.     ldr r1,=0xffffffff  ;all interrupt disable  
  395.     str r1,[r0]  
  396.   
  397.     ldr r0,=INTSUBMSK  
  398.     ldr r1,=0x7fff      ;all sub interrupt disable  
  399.     str r1,[r0]  
  400.   
  401. ;由于启动文件是无法仿真的，因此为了判断该文件中语句的正确与否，往往在需要观察的地方加上一段点亮LED的程序，  
  402. ;这样就可以知道程序是否已经执行到此处  
  403. ;下面方括号内的程序就是点亮LED的小程序  
  404.     [ {FALSE}  ;亮灯用的，可以用来调试用  
  405.         ; GPBDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);  
  406.         ; Led_Display  
  407.         ldr r0,=GPBCON  
  408.         ldr r1,=0x00555555  
  409.         str r1,[r0]  
  410.         ldr r0,=GPBDAT  
  411.         ldr r1,=0x07fe  
  412.         str r1,[r0]  
  413.     ]  
  414.   
  415. ;==================================================================================================================  
  416. ;下列程序是用于设置系统时钟频率  
  417. ;设置PLL的锁定时间常数，以得到一定时间的延时  
  418.       
  419. ;2.根据工作频率设置pll   
  420. ;这里介绍一下计算公式 ;Fpllo=(m*Fin)/(p*2^s) ;m=MDIV+8,p=PDIV+2,s=SDIV   
  421. ;Fpllo必须大于20Mhz小于66Mhz  ;Fpllo*2^s必须小于170Mhz ;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中  
  422. ;#elif (MCLK==40000000) ;#define PLL_M (0x48) ;#define PLL_P (0x3) ;#define PLL_S (0x2)   
  423. ;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2 ;硬件使用晶振为10Mhz,即Fin=10Mhz ;Fpllo=80*10/5*2^2=40Mhz     
  424. ;To reduce PLL lock time, adjust the LOCKTIME register.  
  425. ;==================================================================================================================  
  426.   
  427. ;LOCKTIME 为PLL 锁定时间计数寄存器，重新设定分频值时，PLL 进入锁定，输出稳  
  428. ;定频率的时钟需要一定的时间。这里设置成默认的值，以满足锁定的要求。  
  429.     ldr r0,=LOCKTIME    ;设置pll锁定时间  
  430.     ldr r1,=0xffffff    ;Pll锁定寄存器S3C2410默认为0XFFFFFF  
  431.     str r1,[r0]         ;S3C2440默认为0XFFFFFFFF  
  432.   
  433.     [ PLL_ON_START      ;在option.inc中定义，初始化为真  
  434.         ; Added for confirm clock divide. for 2440.  
  435.         ; Setting value Fclk:Hclk:Pclk  
  436.         ldr r0,=CLKDIVN ;用于设定FCLK，HCLK和PCLK的比例  
  437.         ldr r1,=CLKDIV_VAL      ; 0=1:1:1, 1=1:1:2, 2=1:2:2, 3=1:2:4, 4=1:4:4, 5=1:4:8, 6=1:3:3, 7=1:3:6.，在option.inc中有定义  
  438.         str r1,[r0]  
  439. ; MMU_SetAsyncBusMode and MMU_SetFastBusMode over 4K, so do not call here  
  440. ; call it after copy  
  441. ; [ CLKDIV_VAL>1 ; means Fclk:Hclk is not 1:1.  
  442. ; bl MMU_SetAsyncBusMode  
  443. ; |  
  444. ; bl MMU_SetFastBusMode ; default value.  
  445. ; ]  
  446. ;===============================================================  
  447. ;三星手册里提供的MMU_SetAsyncBusMode 和 MMU_SetFastBusMode 函数都在4K代码  
  448. ;以上（三星2440芯片就提供4K的内部SRAM）,如果你想你编译出来的程序能在NAND  
  449. ;上运行的话,就不能在这调用这两函数了.如果你不要求的话,你就可以直接调用.  
  450. ;下面的代码就是实现和上面两函数一样的功能. 利用的协处理器的命令实现了对  
  451. ;总线模式的设置  
  452. ;===============================================================  
  453.     ;program has not been copied, so use these directly  
  454.         [ CLKDIV_VAL>1       ; means Fclk:Hclk is not 1:1. ;if FCLK：HCLK≠1：1  
  455.             ;设置时钟模式为异步模式  
  456.             mrc p15,0,r0,c1,c0,0  
  457.             orr r0,r0,#0xc0000000;R1_nF:OR:R1_iA  
  458.             mcr p15,0,r0,c1,c0,0  
  459.             |  
  460.             ;设置时钟模式为快速总线模式  
  461.             mrc p15,0,r0,c1,c0,0  
  462.             bic r0,r0,#0xc0000000;R1_iA:OR:R1_nF  
  463.             mcr p15,0,r0,c1,c0,0  
  464.         ]  
  465.           
  466. ;========================================================================================================  
  467. ;配置UPLL  
  468. ;按照手册中的计算公式，确定MDIV、PDIV和SDIV  
  469. ;得到当系统输入时钟频率为12MHz的情况下，UCLK输出频率为48MHz  
  470. ;S3C2440有两个PLL（phase locked loop）一个是MPLL，一个是UPLL。  
  471. ;MPLL用于CPU及其他外围器件，UPLL用于USB。专门用于驱动USB host/Device。  
  472. ;并且驱动USB host/Device的频率必须为48MHz  
  473. ;========================================================================================================  
  474.         ldr r0,=UPLLCON  
  475.         ldr r1,=((U_MDIV<<12)+(U_PDIV<<4)+U_SDIV)               ;Fin = 12.0MHz, UCLK = 48MHz  
  476.         str r1,[r0]  
  477.         ;等待至少7个时钟周期，以保证系统的正确配置  
  478.         nop ; Caution: After UPLL setting, at least 7-clocks delay must be inserted for setting hardware be completed.  
  479.         nop  
  480.         nop  
  481.         nop  
  482.         nop  
  483.         nop  
  484.         nop  
  485.         ;Configure MPLL  
  486.         ldr r0,=MPLLCON  
  487.         ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV)               ;Fin = 12.0MHz, FCLK = 400MHz  
  488.         str r1,[r0]  
  489.     ]  
  490.   
  491. ;=======================================================================================  
  492. ;查看是否是由睡眠状态启动，如果是则跳转到WAKEUP_SLEEP状态  
  493. ;从SLEEP模式下被唤醒，类似于RESET引脚被触发，因此它也要从0x0处开始执行  
  494. ;在此处要判断是否是由SLEEP模式唤醒引起的复位  
  495. ;Check if the boot is caused by the wake-up from SLEEP mode.  
  496.     ldr r1,=GSTATUS2  
  497.     ldr r0,[r1]  
  498.     tst r0,#0x2  
  499.     ;是从休眠模式唤醒,跳转到SLEEP_WAKEUP handler.  
  500.     ;In case of the wake-up from SLEEP mode, go to SLEEP_WAKEUP handler.  
  501.     bne WAKEUP_SLEEP  
  502. ;=======================================================================================  
  503.   
  504. ;初始化内存控制器其实就是对S3C2440 的memory bank 进行设置，使其扩展的存储器  
  505. ;或外部设备能够被处理器通过内存控制器正确读写。由于S3C2440 的最终应用程序是在  
  506. ;SDRAM（bank6）中运行，并与C 语言变量等的用户数据，各种模式的堆栈，中断向量表，  
  507. ;都被定位在SDRAM 的空间，所以它必须在涉及这些处理之前完成初始化工作。  
  508. ;============================================================================================  
  509. ;设置存储器控制寄存器，此段代码把13个存储控制器的内容批量的读取到了对应的特殊功能寄存器中  
  510. ;首先是有一个数据区SMRDATA，在程序的后面有定义，这个数据区给13个寄存器分配52字节的地址空间。  
  511. ;在下面的代码中，r0是这个数据区的起始地址，r2是数据区的结束地址，r1是寄存器的起始地址。  
  512. ;这样，用一个判断语句 cmp r2, r0  
  513. ; bne %B0，就可以把内存中的数据赋给这13个存储控制寄存器了。  
  514. ;============================================================================================  
  515. ;设置一个被唤醒复位后的起始点地址标号，可以把它保存到GSTATUS3中  
  516. ;导出该地址标号，以便在C语言程序中使用      
  517.     EXPORT StartPointAfterSleepWakeUp  
  518. StartPointAfterSleepWakeUp  
  519.   
  520. ;设置内存控制寄存器  
  521. ;关于内存控制寄存器一共有以BWSCON为开始的连续放置的13个寄存器，我们要一次性批量完成这13个寄存器的配置  
  522. ;因此开辟一段以SMRDATA为地址起始点的13个字单元空间，按顺序放入要写入的13个寄存器内容  
  523.     ;Set memory control registers   ;adr装载相对地址(l后缀：long(大范围寻址))，ldr装载绝对地址  
  524.     adrl    r0,SMRDATA      ;canot use ldr r0,=SMRDATA; 得到SMRDATA空间的首地址 起始位置 依次为BANKCON0 BANKCON1 BANKCON2 ........  
  525.     ldr r1,=BWSCON  ;BWSCON Address 在2440addr.inc中定义 ；得到BWSCON的地址  
  526.     add r2, r0, #52 ;End address of SMRDATA ；得到SMRDATA空间的末地址  
  527.   
  528. 0  
  529.     ldr r3, [r0], #4  ;读取R0地址的数据到R3 R0=R0+4   读取SMRDATA 数组(BWSCON BANKCON0 ....)的值  
  530.     str r3, [r1], #4   ;读取R3的数据到R1地址内存中R1=R1+4  赋给BWSON BANKCON0 ....寄存器  
  531.     cmp r2, r0  
  532.     bne %B0  ;当不相等时跳到上面那个标号 0  ， B表示backward（往后—上）  
  533.   
  534. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;  
  535. ;;;;;;;;;;;;;       When EINT0 is pressed,  Clear SDRAM   
  536. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;  
  537. ; check if EIN0 button is pressed  
  538. ;这一段检测EINT0是否被按下，假如EINT0被按下，则清空SDRAM  
  539.     ldr r0,=GPFCON  ;加载地址，在2440addr.inc中定义  
  540.     ldr r1,=0x0  
  541.     str r1,[r0]     ;置F(0:15)input  
  542.     ldr r0,=GPFUP  
  543.     ldr r1,=0xff  
  544.     str r1,[r0]     ;不使用上拉电阻  
  545. ;配置GPF  
  546.     ldr r1,=GPFDAT  ; GPFDAT=0xff  
  547.     ldr r0,[r1]  
  548.     bic r0,r0,#(0x1e<<1)  ; bit clear ;仅保留第1位数据，其他清0  
  549.     tst r0,#0x1          ;判断第1位  
  550.     bne %F1              ;不为0表示按钮没有被按下，则向前跳转，不执行清空SDRAM  
  551.       
  552.       
  553.   
  554. ; Clear SDRAM Start  
  555.     ldr r0,=GPFCON  
  556.     ldr r1,=0x55aa    
  557.     str r1,[r0]        ;GPF7~4为输出，GPF3~0为中断  
  558.     ldr r0,=GPFDAT  
  559.     ldr r1,=0x0  
  560.     str r1,[r0]  ;控制LED灯显示  
  561.   
  562.     mov r1,#0  
  563.     mov r2,#0  
  564.     mov r3,#0  
  565.     mov r4,#0  
  566.     mov r5,#0  
  567.     mov r6,#0  
  568.     mov r7,#0  
  569.     mov r8,#0  
  570.       
  571.     ldr r9,=0x4000000   ;64MB   ;64MB的SDRAM，0x30000000----0x34000000  
  572.     ldr r0,=0x30000000  
  573. 0     
  574.     stmia   r0!,{r1-r8}   
  575.     subs    r9,r9,#32   
  576.     bne %B0  
  577.   
  578. ;Clear SDRAM End  
  579.   
  580. 1  
  581.   
  582.     ;Initialize stacks  
  583.     bl  InitStacks      ;初始化堆栈  
  584. ;（调试时在SDRAM中取指运行，否则在norflash中取指执行，或者nandflash启动模式下在4kb的SRAM中取指执行）  
  585.   
  586. ;======================================================================  
  587. ;这段程序能在nor nand flash 运行，也可以在内存中运行。在nor nand flash运行，需要拷贝数据；  
  588. ;======================================================================  
  589. ;======================================================================  
  590.       
  591.     ;检测引脚OM[1:0]，如果OM[1:0]!=0,选择从NOR Flash启动，如果OM[1:0]==0，则表示从nand flash启动  
  592.     ldr r0, =BWSCON  
  593.     ldr r0, [r0]  
  594.     ands    r0, r0, #6      ;OM[1:0] != 0, NOR FLash boot   ;OM[1:0] != 0, NOR FLash 或者内存启动  
  595.     bne copy_proc_beg       ;do not read nand flash         ;不用读取 nand flash;  
  596.     adr r0, ResetEntry      ;OM[1:0] == 0, NAND FLash boot  ;OM[1:0] == 0, NAND FLash 启动  
  597.     cmp r0, #0          ;if use Multi-ice,                  ;再比较入口是否为0地址处，如果不是则用了仿真器  
  598.                                                             ;测试是不是处于调试模式  
  599.     bne copy_proc_beg       ;do not read nand flash for boot    ;用仿真器的情况也不要用 nand flash启动  
  600.                               ;此时处于调试状态，程序在SDRAM中运行，不需要从nandflash中拷贝数据  
  601.     ;nop  
  602.   
  603.       
  604. ;不是处于调试模式，而是从板从nandflash启动  
  605. ;此时4KB的片上SRAM（0x0000_0000--0x0000_0fff）存储nandfllash的前4KB程序，所以此时是从SRAM中取指令执行  
  606. nand_boot_beg       ;这一段代码完成从NAND读代码到RAM   
  607.     [ {TRUE}  
  608.         bl RdNF2SDRAM  ;执行从nandflash拷贝数据子程序  
  609.         ;此时nandflash代码已经被拷贝到了SDRAM中  
  610.     ]  
  611.     ;nand flash启动，拷贝程序到steppingstone区域  
  612.     ldr pc, =copy_proc_beg  
  613.     ;拷贝完成后进入SDRAM中执行程序（在运行域中执行代码），pc指向SDRAM中代码  
  614. ;===========================================================  
  615.   
  616. ;若是在板从norflash启动，先把用来’拷贝装载域RO段到运行域的程序‘拷贝到SDRAM中，  
  617. ;并在SDRAM中执行此程序，以便快速完成装载域RO段程序到运行域的拷贝  
  618. ;若是处于调试状态，或者nandfalsh启动模式的拷贝代码已经完成，则不执行’拷贝装载域RO段到运行域‘的拷  
  619. ;贝操作，直接跳到初始化ZI段的子程序处执行  
  620. copy_proc_beg  
  621. ;若是norflash启动模式，r0指向的是装载域RO段起始地址，否则r0指向的是运行域的RO段起始地址  
  622.     adr r0, ResetEntry      ;装载地址,ResetEntry值->r0      
  623. ;r1指向运行域RO段起始地址  ;|Image$RO$Base|     
  624.     ldr r2, BaseOfROM       ;BaseOfROM值(后面有定义)->r2  
  625.     cmp r0, r2              ;比较RO,R2  
  626. ;如果相等的话(在内存运行 --- ice -- 无需复制code区中的ro段，但需要复制code区中的rw段),TopOfROM->r0  
  627.     ldreq   r0, TopOfROM    ;如果相等的话(说明在内存中运行,或是从NOR Flash启动),TopOfROM->r0  
  628.     beq InitRam             ;同时跳到InitRam  
  629.       
  630. ;=========================================================  
  631. ;下面这个是针对代码在NOR FLASH时的拷贝方法  
  632. ;功能为把从ResetEntry起,TopOfROM-BaseOfROM大小的数据拷到BaseOfROM  
  633. ;TopOfROM和BaseOfROM为|Image$RO$Limit|和|Image$RO$Base|  
  634. ;|Image$RO$Limit|和|Image$RO$Base|由连接器生成  
  635. ;为生成的代码的代码段运行时的起启和终止地址  
  636. ;BaseOfBSS和BaseOfZero为|Image$RW$Base|和|Image$ZI$Base|  
  637. ;|Image$RW$Base|和|Image$ZI$Base|也是由连接器生成  
  638. ;两者之间就是初始化数据的存放地放  
  639. ; --在加载阶段，不存在ZI区域--  
  640. ;=======================================================  
  641.     ldr r3, TopOfROM  
  642. 0       ;ldm批量数据加载指令,ldm后的ia表示每次传送后地址+1  
  643.     ldmia   r0!, {r4-r7}    ;运行一次后R0=（R4到R7寄存器个数)*4   开始时，r0 = ResetEntry --- source  
  644.     stmia   r2!, {r4-r7}    ;stm批量数据存储指令,!的作用，当数据传输完毕，将最后的地址写入R2 开始时，r2 = BaseOfROM  --- destination  
  645.     cmp r2, r3              ;终止条件：复制了TopOfROM-BaseOfROM大小  
  646.       ; b跳转  条件：CC/LO  C=0  无符号数小于  
  647.     bcc %B0                 ;C标志置位/大于或小于时向后跳转到0标号处  
  648.                             ;最终实现拷贝数据到ram  
  649.     ;修正非字对齐的情况  
  650.     ; 下面2行目的是为了计算正确的r0（必须使之指向code区中的rw域开始处）  
  651.     sub r2, r2, r3          ;r2=BaseOfROM-TopOfROM=(-)代码长度  
  652.     sub r0, r0, r2          ;r0=ResetEntry-(-)代码长度=ResetEntry+代码长度        
  653.           
  654. InitRam       
  655. ;复制代码加载位置中的RM区到|Image$RW$Base|  
  656.     ldr r2, BaseOfBSS       ;装载数值RWBase    ;BaseOfBSS->r2 ,  BaseOfBSS = |Image$RW$Base|  
  657.     ldr r3, BaseOfZero      ;装载数值ZIBase     ;BaseOfZero->r3 , BaseOfZero = |Image$ZI$Base|  
  658.     ;下面循环体为复制已初始化的全局变量  
  659. 0  
  660.     cmp r2, r3              ;如果R2<R3,将ResetEntry处的内容传送到R1   ;比较BaseOfBSS和BaseOfZero  
  661.     ldrcc   r1, [r0], #4    ;利用R1做中转 条件：CC/LO  C=0  无符号数小于  
  662.     strcc   r1, [r2], #4    ;将ResetEntry处的内容,送到ZIBase地址处  
  663. ;当代码在内存中运行时，r0(初始值) = TopOfROM.这之后的BaseOfZero-BaseOfBSS仍属于code，需拷贝到BaseOfBSS  
  664.     bcc %B0   
  665.   
  666.     ;下面循环体是为未初始化的全局变量赋值为0  
  667.     mov r0, #0  
  668.     ldr r3, EndOfBSS        ;装载数值ZILimit ;EndOfBSS = |Image$ZI$Limit|  
  669. 1     
  670.     cmp r2, r3  
  671.     strcc   r0, [r2], #4  
  672.     bcc %B1 ;初始化运行域ZI段  
  673.       
  674.     ldr pc, =%F2        ;goto compiler address  ;goto compiler address  ;进入SDRAM中运行程序  
  675. 2  
  676.       
  677. ;   [ CLKDIV_VAL>1       ; means Fclk:Hclk is not 1:1.   ; FCLK>HCLK时  
  678. ;   bl  MMU_SetAsyncBusMode    ;设置为异步模式  
  679. ;   |  
  680. ;   bl MMU_SetFastBusMode   ; default value.   ;设置为快速模式  
  681. ;   ]  
  682.       
  683.   
  684. ;===========================================================  
  685. ; 进入C语言前的最后一步了,就是把我们用说查二级向量表  
  686. ; 的中断例程安装到一级向量表(异常向量表)里.  
  687. ;//5.设置缺省中断处理函数  
  688.     ; Setup IRQ handler  
  689.     ldr r0,=HandleIRQ   ;This routine is needed  ;IRQ中断服务程序存储地址  
  690.     ldr r1,=IsrIRQ  ;if there is not 'subs pc,lr,#4' at 0x18, 0x1c  ;中断查询子程序入口地址  
  691.     str r1,[r0]  ;将中断查询子程序入口地址放入IRQ中断服务程序存储处  
  692.   
  693.   
  694.     [ :LNOT:THUMBCODE  ;if thumbcode={false} bl main   L代表logic变量  ;如果不是THUMB指令状态  
  695.         bl  Main    ;Do not use main() because ...... ;不要用main()因为main()是ADS默认入口，编译器会添加其他代码  
  696.         ;ldr pc, =Main ;  
  697.         b   .       ;跳转到Main不成功则挂起  
  698.     ]  
  699. ;if thumbcod={ture}  
  700.     [ THUMBCODE  ;for start-up code for Thumb mode ;若是处于THUMB指令状态  
  701.         orr lr,pc,#1  ;将pc最低位置1   （当操作数寄存器的状态位(位[0])为1时,执行BX指令进入Thumb状态.  
  702.                      ; (如果处理器在Thumb状态进入异常,则当异常处理返回时,自动转换到Thumb状态))  
  703.         bx  lr        ;转换到THUMB模式  
  704.         CODE16       ;下面的代码（C代码）按THUMB编译  
  705.         bl  Main    ;Do not use main() because ......     ;进入Main()函数执行  
  706.         b   .  
  707.         CODE32    ;后面的指令按ARM指令编译  
  708.     ]  
  709.   
  710. ;堆栈初始化的顺序决定系统最后运行在哪种处理器模式，最后初始化哪种模式的堆栈，系  
  711. ;统就运行在哪种模式。  
  712. ;function initializing stacks  
  713. InitStacks  
  714.     ;Do not use DRAM,such as stmfd,ldmfd......（这些指令在堆栈建立之后才能用）  
  715.     ;SVCstack is initialized before  
  716.     ;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'  
  717.     mrs r0,cpsr  
  718. ;UNDEFMODE   EQU  0x1b ;未定义模式  
  719. ;MODEMASK    EQU  0x1f ;模式掩码  
  720. ;NOINT       EQU  0xc0 ;无中断模式              这三行是上面定义的  
  721.     bic r0,r0,#MODEMASK  ;(屏蔽低5位)  
  722.     orr r1,r0,#UNDEFMODE|NOINT ; (屏蔽6、7位和选择未定义模式)  
  723.     msr cpsr_cxsf,r1        ;UndefMode ;关于cpsr_cxsf可以阅读http://apps.hi.baidu.com/share/detail/21740046  
  724.     ldr sp,=UndefStack      ; UndefStack=0x33FF_5C00 （这个在上面有定义)  
  725.       
  726. ;先通过mrs 指令将状态寄存器值读取到r0，然后将r0 对应的处理器模式为修改成未定  
  727. ;义指令中止模式，再写回状态寄存器使处理器真正切换到未定义指令中止模式，这就  
  728. ;是“读出-修改-写回”的方式来修改状态寄存器的内容。最后将该模式的堆栈指针sp 指  
  729. ; 向UndefStack 定义的地址，其他的模式操作方式也是一样  
  730.     orr r1,r0,#ABORTMODE|NOINT  
  731.     msr cpsr_cxsf,r1        ;AbortMode （数据访问）中止模式  
  732.     ldr sp,=AbortStack      ; AbortStack=0x33FF_6000  
  733.   
  734.     orr r1,r0,#IRQMODE|NOINT   ;IRQMode   ;中断模式  
  735.     msr cpsr_cxsf,r1        ;IRQMode  
  736.     ldr sp,=IRQStack        ; IRQStack=0x33FF_7000  
  737.   
  738.     orr r1,r0,#FIQMODE|NOINT  
  739.     msr cpsr_cxsf,r1        ;FIQMode  ;快速中断模式  
  740.     ldr sp,=FIQStack        ; FIQStack=0x33FF_8000  
  741.   
  742.     bic r0,r0,#MODEMASK|NOINT  
  743.     orr r1,r0,#SVCMODE  
  744.     msr cpsr_cxsf,r1        ;SVCMode  ;管理模式  
  745.     ldr sp,=SVCStack        ; SVCStack=0x33FF_5800  
  746.   
  747.     ;USER mode has not be initialized.  
  748.   
  749. ;系统模式和用户模式共用一个栈空间，因此不用再重复设置用户模式堆栈  
  750. ;系统复位后进入的是SVC模式，而且各种模式下的lr不同，因此要想从该函数内返回，  
  751. ;要首先切换到SVC模式，再使用lr，这样可以正确返回了  
  752.     mov pc,lr  
  753.     ;The LR register will not be valid if the current mode is not SVC mode.  
  754.       
  755. ;LTORG用于声明一个文字池,在使用LDR伪指令时,要在适当的地址加入LTORG声明  
  756. ;文字池,这样就会把要加载的数据保存在文字池内,再用 ARM 的加载指令读出数据.(若  
  757. ;没有使用 LTORG 声明文字池,则汇编器会在程序末尾自动声明.)  
  758. ;LTORG 伪指令常放在无条件跳转指令之后,或者子程序返回指令之后,这样处理器  
  759. ;就不会错误地将文字池中的数据当作指令来执行.  
  760.     LTORG  
  761.   
  762.       
  763. ;这段程序的开始使用DATA 伪操作指明SMRDATA 标号处作为一段数据，而非代码。  
  764. ;接下来就用DCD 分配一个字的内存单元，一共13 个字数据。  
  765.   
  766. SMRDATA DATA  ;存储器控制寄存器的定义区  
  767. ;GCS0->SST39VF1601  
  768. ;GCS1->16c550  
  769. ;GCS2->IDE  
  770. ;GCS3->CS8900  
  771. ;GCS4->DM9000  
  772. ;GCS5->CF Card  
  773. ;GCS6->SDRAM  
  774. ;GCS7->unused  
  775. SMRDATA DATA    ;SMRDATA是段名，DATA是属性（定义为数据段）  
  776. ; Memory configuration should be optimized for best performance  
  777. ; The following parameter is not optimized.  
  778. ; Memory access cycle parameter strategy  
  779. ; 1) The memory settings is  safe parameters even at HCLK=75Mhz.  
  780. ; 2) SDRAM refresh period is for HCLK<=75Mhz.  
  781. ;DCD指令用于分配一片连续的字存储单元并用伪指令中指定的表达式初始化  
  782. ;DCD用于分配一段字内存单元,并用伪指令中的expr初始化.DCD伪指令分配的内存  
  783. ;需要字对齐,一般可用来定义数据表格或其它常数.&与DCD 同义.  
  784. ;下面可以看一下这个http://budapeng2000.blog.sohu.com/171752218.html  
  785. ;或百度一下“终极内存技术指南”(这个挺难理解的)  
  786.     DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))  
  787.     DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))   ;GCS0  
  788.     DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))   ;GCS1  
  789.     DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))   ;GCS2  
  790.     DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))   ;GCS3  
  791.     DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))   ;GCS4  
  792.     DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))   ;GCS5  
  793.     DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6  
  794.     DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7  
  795.     DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Tsrc<<18)+(Tchr<<16)+REFCNT)  
  796.   
  797.     DCD 0x32        ;SCLK power saving mode, BANKSIZE 128M/128M  
  798.   
  799.     DCD 0x30        ;MRSR6 CL=3clk  
  800.     DCD 0x30        ;MRSR7 CL=3clk  
  801.   
  802. BaseOfROM   DCD |Image$RO$Base|  
  803. TopOfROM    DCD |Image$RO$Limit|  
  804. BaseOfBSS   DCD |Image$RW$Base|  
  805. BaseOfZero  DCD |Image$ZI$Base|  
  806. EndOfBSS    DCD |Image$ZI$Limit|  
  807.   
  808.     ALIGN  ;LIGN 伪指令通过添加补丁字节使当前位置满足一定的对齐方式.  
  809.   
  810. ;掉电模式函数  
  811. ;在C语言中定义为：#define EnterPWDN(clkcon) ((void (*)(int))0x20)(clkcon)  
  812. ;Function for entering power down mode  
  813. ; 1. SDRAM should be in self-refresh mode.  
  814. ; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.  
  815. ; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.  
  816. ; 4. The I-cache may have to be turned on.  
  817. ; 5. The location of the following code may have not to be changed.  
  818.   
  819. ;void EnterPWDN(int CLKCON);  
  820. EnterPWDN  
  821.     mov r2,r0       ;r2=rCLKCON   ;r2=rCLKCON 保存原始数据 0x4c00000c 使能各模块的时钟输入 ;r0为该函数输入参数clkcon  
  822.     tst r0,#0x8     ;SLEEP mode?     ;测试bit[3] SLEEP mode? 1=>sleep ;判断clkcon中的第3位，是否要切换到SLEEP模式  
  823.     bne ENTER_SLEEP       ;C=0,即TST结果非0，bit[3]=1  ;切换到SLEEP模式  
  824.        
  825. ;进入PWDN后如果不是sleep则进入stop  
  826. ENTER_STOP  ;//进入Stop mode  
  827. ;设置SDRAM为自刷新方式  
  828.     ldr r0,=REFRESH   ;0x48000024   DRAM/SDRAM refresh config  
  829.     ldr r3,[r0]     ;r3=rREFRESH  
  830.     mov r1, r3  
  831.     orr r1, r1, #BIT_SELFREFRESH     ;BIT_SELFREFRESH EQU (1<<22) ;SDRAM自刷新标志位  
  832.     str r1, [r0]        ;Enable SDRAM self-refresh  
  833.       
  834. ;等待一段时间  
  835.     mov r1,#16          ;wait until self-refresh is issued. may not be needed.  
  836. 0   subs r1,r1,#1  
  837.     bne %B0  
  838.   
  839.     ldr r0,=CLKCON      ;enter STOP mode.  
  840.     str r2,[r0]   ;置第2位，进入IDLE模式  
  841.   
  842.     ;等待一段时间  
  843.     mov r1,#32  
  844. 0   subs r1,r1,#1   ;1) wait until the STOP mode is in effect.  
  845.     bne %B0     ;2) Or wait here until the CPU&Peripherals will be turned-off  
  846.             ;   Entering SLEEP mode, only the reset by wake-up is available.  
  847.   
  848.     ;从IDLE模式下被唤醒，系统从该处继续执行  
  849.     ;取消SDRAM自刷新方式  
  850.     ldr r0,=REFRESH ;exit from SDRAM self refresh mode.  
  851.     str r3,[r0]  
  852.   
  853.     MOV_PC_LR   ;返回，该语句为一个宏定义  
  854.   
  855. ENTER_SLEEP  ;SLEEP模式  
  856.     ;NOTE.  
  857.     ;1) rGSTATUS3 should have the return address after wake-up from SLEEP mode.  
  858.   
  859.     ;设置SDRAM为自刷新方式  
  860.     ldr r0,=REFRESH  
  861.     ldr r1,[r0]     ;r1=rREFRESH  
  862.     orr r1, r1, #BIT_SELFREFRESH  
  863.     str r1, [r0]        ;Enable SDRAM self-refresh  
  864.   
  865.     ;等待一段时间  
  866.     mov r1,#16          ;Wait until self-refresh is issued,which may not be needed.  
  867. 0   subs r1,r1,#1  
  868.     bne %B0  
  869.   
  870.     ;在进入SLEEP模式之前，配置必要的时钟和OFFREFRESH  
  871.     ldr r1,=MISCCR  
  872.     ldr r0,[r1]  
  873.     orr r0,r0,#(7<<17)  ;Set SCLK0=0, SCLK1=0, SCKE=0.  
  874.     str r0,[r1]  
  875.   
  876.     ldr r0,=CLKCON      ; Enter sleep mode  
  877.     str r2,[r0]    ;置第3位，进入SLEEP模式  
  878.   
  879.     b .         ;CPU will die here.  
  880.   
  881. ;从睡眠状态醒过来  
  882. WAKEUP_SLEEP  
  883.     ;Release SCLKn after wake-up from the SLEEP mode.  
  884.     ;设置时钟和OFFREFRESH  
  885.     ldr r1,=MISCCR  
  886.     ldr r0,[r1]  
  887.     bic r0,r0,#(7<<17)  ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.  
  888.     str r0,[r1]  
  889.   
  890.     ;Set memory control registers  
  891.     ;配置内存控制寄存器  
  892.     ldr r0,=SMRDATA  ;be careful! 将标号SMRDATA所标识的地址写入r0 ？？adrl r0, SMRDATA ？？  
  893.     ldr r1,=BWSCON  ;BWSCON Address  
  894.     add r2, r0, #52 ;End address of SMRDATA  
  895. 0  
  896.     ldr r3, [r0], #4  
  897.     str r3, [r1], #4  
  898.     cmp r2, r0  
  899.     bne %B0  
  900.   
  901.     ;等待一段时间  
  902.     mov r1,#256  
  903. 0   subs r1,r1,#1   ;1) wait until the SelfRefresh is released.  
  904.     bne %B0  
  905.   
  906.     ;GSTATUS3存放着想要从SLEEP模式唤醒后的执行地址  
  907.     ldr r1,=GSTATUS3    ;GSTATUS3 has the start address just after SLEEP wake-up  
  908.     ldr r0,[r1]  
  909.   
  910.     mov pc,r0       ;跳转到GSTATUS3存放的地址处  
  911.   
  912. ;=====================================================================  
  913. ; Clock division test  
  914. ; Assemble code, because VSYNC time is very short  
  915. ;=====================================================================  
  916.     EXPORT CLKDIV124  
  917.     EXPORT CLKDIV144  
  918.       
  919. CLKDIV124  
  920.       
  921.     ldr     r0, = CLKDIVN  
  922.     ldr     r1, = 0x3       ; 0x3 = 1:2:4  
  923.     str     r1, [r0]  
  924. ;   wait until clock is stable  
  925.     nop  
  926.     nop  
  927.     nop  
  928.     nop  
  929.     nop  
  930.   
  931.     ldr     r0, = REFRESH  
  932.     ldr     r1, [r0]  
  933.     bic     r1, r1, #0xff  
  934.     bic     r1, r1, #(0x7<<8)  
  935.     orr     r1, r1, #0x470  ; REFCNT135  
  936.     str     r1, [r0]  
  937.     nop  
  938.     nop  
  939.     nop  
  940.     nop  
  941.     nop  
  942.     mov     pc, lr  
  943.   
  944. CLKDIV144  
  945.     ldr     r0, = CLKDIVN  
  946.     ldr     r1, = 0x4       ; 0x4 = 1:4:4  
  947.     str     r1, [r0]  
  948. ;   wait until clock is stable  
  949.     nop  
  950.     nop  
  951.     nop  
  952.     nop  
  953.     nop  
  954.   
  955.     ldr     r0, = REFRESH  
  956.     ldr     r1, [r0]  
  957.     bic     r1, r1, #0xff  
  958.     bic     r1, r1, #(0x7<<8)  
  959.     orr     r1, r1, #0x630  ; REFCNT675 - 1520  
  960.     str     r1, [r0]  
  961.     nop  
  962.     nop  
  963.     nop  
  964.     nop  
  965.     nop  
  966.     mov     pc, lr  
  967.   
  968.   
  969.     ALIGN       ;使得下面的代码按一定规则对齐,  
  970.     ;按照一定的规则对齐，^符号相当于伪指令MAP，用于定义一个结构化的内存表的首地址  
  971.   
  972.     AREA RamData, DATA, READWRITE  
  973. ;在0x33FF_FF00处定义中断向量表  
  974. ;^是MAP的同义词，#是FIELD的同义词  
  975.     ^   _ISR_STARTADDRESS       ; _ISR_STARTADDRESS=0x33FF_FF00  
  976. HandleReset     #   4           ;^符号相当于伪指令MAP，用于定义一个结构化的内存表的首地址  
  977. HandleUndef     #   4           ;HandleUndef+4;  
  978. HandleSWI       #   4  
  979. HandlePabort    #   4  
  980. HandleDabort    #   4  
  981. HandleReserved  #   4  
  982. HandleIRQ       #   4  
  983. HandleFIQ       #   4  
  984.   
  985. ;Do not use the label 'IntVectorTable',  
  986. ;The value of IntVectorTable is different with the address you think it may be.  
  987. ;IntVectorTable  
  988. ;@0x33FF_FF20  
  989. HandleEINT0     #   4  
  990. HandleEINT1     #   4  
  991. HandleEINT2     #   4  
  992. HandleEINT3     #   4  
  993. HandleEINT4_7   #   4  
  994. HandleEINT8_23  #   4  
  995. HandleCAM       #   4       ; Added for 2440.  
  996. HandleBATFLT    #   4  
  997. HandleTICK      #   4  
  998. HandleWDT       #   4  
  999. HandleTIMER0    #   4  
  1000. HandleTIMER1    #   4  
  1001. HandleTIMER2    #   4  
  1002. HandleTIMER3    #   4  
  1003. HandleTIMER4    #   4  
  1004. HandleUART2     #   4  
  1005. ;@0x33FF_FF60  
  1006. HandleLCD       #   4  
  1007. HandleDMA0      #   4  
  1008. HandleDMA1      #   4  
  1009. HandleDMA2      #   4  
  1010. HandleDMA3      #   4  
  1011. HandleMMC       #   4  
  1012. HandleSPI0      #   4  
  1013. HandleUART1     #   4  
  1014. HandleNFCON     #   4       ; Added for 2440.  
  1015. HandleUSBD      #   4  
  1016. HandleUSBH      #   4  
  1017. HandleIIC       #   4  
  1018. HandleUART0     #   4  
  1019. HandleSPI1      #   4  
  1020. HandleRTC       #   4  
  1021. HandleADC       #   4  
  1022. ;@0x33FF_FFA0  
  1023.   
  1024. END  
返回
【上篇】
【下篇】

作者:

抱歉!评论已关闭.

返回首页

Copyright © 2013-2018 学步园  保留所有权利.
软文销售 QQ客服：2265327166 点击这里给我发消息（其他合作也可洽谈）
必威体育
必威电竞