学步园

 是否经常奔波于公司/学校 和 家里?
是否疲于更改自己的本本网络配置?
如果你是以上两种人之一,请看下文!

这是自己写的一个批处理文件，全自动配置IP地址，网关，dns
如果有手提电脑，经常修改网络配置的哥们，使用这个工具太方便了!
以下为源代码.

@echo off
title Network Configuration Application---Made by 风逐云 [email]NicholasMaxwell@msn.com[/email] QQ:55730050
mode con: cols=80 lines=23
ECHO. ==================Configurating, Please Wait==================
ECHO. ==================Network Configuration Application================== > netcfg.log
color 1a
ECHO. 


::::::::::::::::::::::::::::::::::::::::::
:: 用户定义段
:: 如需自定义，请修改这里
:: 
:: 说明:
:: addr_name..........网络连接名称
:: addr_ip............IP地址
:: addr_mask..........子网掩码
:: addr_gateway.......网关
:: addr_dns_pri.......主DNS
:: addr_dns_sec.......副DNS
set addr_name=本地连接
set addr_ip=192.168.0.63
set addr_mask=255.255.255.0
set addr_gateway=192.168.0.110
set addr_dns_pri=202.101.172.35
set addr_dns_sec=192.168.0.110
::::::::::::::::::::::::::::::::::::::::::

echo addr_name=%addr_name% >> netcfg.log
echo addr_ip=%addr_ip% >> netcfg.log
echo addr_mask=%addr_mask% >> netcfg.log
echo addr_gateway=%addr_gateway% >> netcfg.log
echo addr_dns_pri=%addr_dns_pri% >> netcfg.log
echo addr_dns_sec=%addr_dns_sec% >> netcfg.log

:::::::::::::::::::::::::::::::::::::::
::设置ip, gateway, and mask
:: if ip=null
:IP
ECHO. Applying IP set... 
ECHO. Applying IP set... >> netcfg.log
if defined addr_ip (netsh interface ip set address name=%addr_name% source=static addr=%addr_ip% mask=%addr_mask% >> netcfg.log) else (netsh interface ip set address name=%addr_name% source=dhcp >> netcfg.log)
GOTO GATEWAY

:GATEWAY
ECHO. Applying gateway set... 
ECHO. Applying gateway set... >> netcfg.log
NETSH INTERFACE IP DELETE ADDR NAME=%addr_name% GATEWAY=ALL >> netcfg.log
IF DEFINED addr_gateway (NETSH INTERFACE IP ADD ADDR NAME=%addr_name% GATEWAY=%addr_gateway% GWMETRIC=1 >> netcfg.log)
GOTO DNS

:DNS
ECHO. Applying DNS set... 
ECHO. Applying DNS set... >> netcfg.log
netsh interface ip delete dns name=%addr_name% addr=all >> netcfg.log
IF DEFINED addr_dns_pri (netsh interface ip add dns name=%addr_name% addr=%addr_dns_pri% index=1 >> netcfg.log)
IF DEFINED addr_dns_sec (netsh interface ip add dns name=%addr_name% addr=%addr_dns_sec% index=2 >> netcfg.log)
GOTO SHOW

:SHOW
ECHO. 
ECHO. 
ECHO. 
ECHO. Retult: ====================================================================
ECHO. Retult: ==================================================================== >> netcfg.log
IPCONFIG /ALL
IPCONFIG /ALL >> netcfg.log
pause