在Startup.s文件中包含一个startup的入口函数，该函数为EBOOT的最开始的入口。在系统上电或者冷启动的时候，这是第一个被执行的函数。该函数都是由汇编语言编写的，完成基于硬件平台的最初的初始化，也就是CPU的相关初始化，如果有必要，也可以在这里对外围的设备进行初始化。该函数执行到最后，会跳转到C语言的入口，一般是Main函数，或者叫做EBootMain函数。
这里要多说的一件事情就是在BSP当中存在两个Startup.s文件，一个是EBOOT的Startup.s用于EBOOT本身，另一个是OAL的Startup.s用于WinCE内核。在很多情况下，两个Startup.s所完成的任务非常的相近，所以一般都会合并成一个Startup.s来完成相应的功能。比如你在EBOOT的Startup.s中完成了相关的初始化操作以后，在OAL的Startup.s中只需要include位于EBOOT下的Startup.s就可以了。当然，这两个Startup.s也许不能完全一样，所以不管是真的存在两个Startup.s文件还是共用一个Startup.s文件，你可能都需要在Startup.s中通过条件编译或者判断某个变量的方法来区分。
下面具体说一下在Startup.s中，到底应该做些什么事情：
1.在系统上电或者复位时，先将CPU设置到正确的模式下面。一般CPU本身会有几种模式，比如对于ARM来说，这个时候一般会设置为管理模式。
2.关闭所有的CPU中断。
3.关闭内存管理单元MMU和TLB。
4.关闭写缓冲和Cache。
5.初始化内存控制器。
6.设置CPU的PLL，设置时钟。
7.创建堆栈。
8.设置并打开MMU和Cache。
9.如果需要，自己拷贝EBOOT从Flash到RAM中。
10.跳转到C代码中，一般是Main函数或者EBootMain函数。
下面以ARM为例，来看一个Startup.s的模板：
STARTUPTEXT
LEAF_ENTRY StartUp
; 设置ARM的CPSR寄存器来设置ARM为管理模式并屏蔽所有中断
mov r0, #(SVC32Mode :OR: NoINTS)
msr cpsr_c, r0
; 设置CP15协处理器，关闭MMU和Cache
ldr r0, =CP15ControlInit
WRMMU_STATE r0
ldr r0, =CP15AuxControlInit
WRMMU_AUX_STATE r0
; 刷新TLB表和Cache
mov r0, #0x0
WRMMU_FlushTB r0
WRCACHE_FlushIDC r0
; 释放写缓冲
mov r0, #0
mcr p15, 0, r0, c7, c10, 4
CPWAIT
; 创建一个临时的堆栈，使用SRAM中的头32KB
ldr sp, =(CPU_SRAM0 + SZ_32K - 4)
bl disableInts ; 屏蔽外部中断
bl initUART ; 初始化串口
bl initClocks ; 初始化系统时钟
bl initStaticMem ; 初始化Flash片选控制器
bl initSDRAM ; 初始化SDRAM控制器
bl sizeSDRAM ; 返回SDRAM的大小
IF EBOOT
; 重定位Flash中的代码到RAM中
bl EverythingRelocate
; 重定位成功后，跳转到RealStartup新地址运行，否则接着运行
cmp r0, #-1
movne pc, r0
ENDIF
RealStartup
IF EBOOT
bl EbootMain ; 跳转到EbootMain函数，就是EBOOT的C语言代码中
ELSE
adr r0, OEMAddressTable ; r0 = physical address of OEMMemoryMap
bl KernelStart ; 跳转到KernelStart函数，并传入物理虚拟地址映射表
ENDIF
; 这里是一个死循环，代码应该永远也执行不到这里
spin b spin
ENTRY_END
整个Startup.s的流程就是这样，一般开发这段代码需要对处理器及汇编语言比较了解，其实也不是很复杂，就是做最基本的初始化，该函数一般也就几百行。调试可能稍微费劲一些，在最开始的时候一般通过点灯(Led)的方式来调试，就是说写个小的汇编函数，通过把GPIO拉高拉低来点亮和熄灭LED灯。然后在Startup.s中的不同位置调用该函数从而判断函数是否执行到相应的地方。
本文来自CSDN博客，转载请标明出处：http://blog.csdn.net/nanjianhui/archive/2008/10/12/3065291.aspx