学步园

1.分页我用的是一个常用的SQL存储过程

SET QUOTED_IDENTIFIER ON 
GO
SET ANSI_NULLS ON 
GO

ALTER  PROC PROCE_PageView
(
@tbname     nvarchar(100),               --要分页显示的表名
@FieldKey   nvarchar(1000),      --用于定位记录的主键(惟一键)字段,可以是逗号分隔的多个字段
@PageCurrent int=1,               --要显示的页码
@PageSize   int=10,                --每页的大小(记录数)
@FieldShow nvarchar(1000)='',      --以逗号分隔的要显示的字段列表,如果不指定,则显示所有字段
@FieldOrder nvarchar(1000)='',      --以逗号分隔的排序字段列表,可以指定在字段后面指定DESC/ASC
@WhereString    nvarchar(1000)=N'',     --查询条件
@RecordCount int OUTPUT             --总记录数
)
AS
SET NOCOUNT ON
--检查对象是否有效
--IF OBJECT_ID(@tbname) IS NULL
--BEGIN
--    RAISERROR(N'对象"%s"不存在',1,16,@tbname)
--    RETURN
--END
--IF OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTable')=0
--    AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsView')=0
--    AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTableFunction')=0
--BEGIN
--    RAISERROR(N'"%s"不是表、视图或者表值函数',1,16,@tbname)
--    RETURN
--END

--分页字段检查
IF ISNULL(@FieldKey,N'')=''
BEGIN
    RAISERROR(N'分页处理需要主键（或者惟一键）',1,16)
    RETURN
END

--其他参数检查及规范
IF ISNULL(@PageCurrent,0)<1 SET @PageCurrent=1
IF ISNULL(@PageSize,0)<1 SET @PageSize=10
IF ISNULL(@FieldShow,N'')=N'' SET @FieldShow=N'*'
IF ISNULL(@FieldOrder,N'')=N''
    SET @FieldOrder=N''
ELSE
    SET @FieldOrder=N'ORDER BY '+LTRIM(@FieldOrder)
IF ISNULL(@WhereString,N'')=N''
    SET @WhereString=N''
ELSE
    SET @WhereString=N'WHERE ('+@WhereString+N')'

--如果@RecordCount为NULL值,则计算总页数(这样设计可以只在第一次计算总页数,以后调用时,把总页数传回给存储过程,避免再次计算总页数,对于不想计算总页数的处理而言,可以给@RecordCount赋值)
IF @RecordCount IS NULL
BEGIN
    DECLARE @sql nvarchar(4000)
    SET @sql=N'SELECT @RecordCount=COUNT(*)'
        +N' FROM '+@tbname
        +N' '+@WhereString
    EXEC sp_executesql @sql,N'@RecordCount int OUTPUT',@RecordCount OUTPUT
END

--计算分页显示的TOPN值
DECLARE @TopN varchar(20),@TopN1 varchar(20)
SELECT @TopN=@PageSize,
    @TopN1=(@PageCurrent-1)*@PageSize

--第一页直接显示
IF @PageCurrent=1
    EXEC(N'SELECT TOP '+@TopN
        +N' '+@FieldShow
        +N' FROM '+@tbname
        +N' '+@WhereString
        +N' '+@FieldOrder)
ELSE
BEGIN
    --处理别名
    IF @FieldShow=N'*'
        SET @FieldShow=N'a.*'

    --生成主键(惟一键)处理条件
    DECLARE @Where1 nvarchar(4000),@Where2 nvarchar(4000),
        @s nvarchar(1000),@Field sysname
    SELECT @Where1=N'',@Where2=N'',@s=@FieldKey
    WHILE CHARINDEX(N',',@s)>0
        SELECT @Field=LEFT(@s,CHARINDEX(N',',@s)-1),
            @s=STUFF(@s,1,CHARINDEX(N',',@s),N''),
            @Where1=@Where1+N' AND a.'+@Field+N'=b.'+@Field,
            @Where2=@Where2+N' AND b.'+@Field+N' IS NULL',
            @WhereString=REPLACE(@WhereString,@Field,N'a.'+@Field),
            @FieldOrder=REPLACE(@FieldOrder,@Field,N'a.'+@Field),
            @FieldShow=REPLACE(@FieldShow,@Field,N'a.'+@Field)
    SELECT @WhereString=REPLACE(@WhereString,@s,N'a.'+@s),
        @FieldOrder=REPLACE(@FieldOrder,@s,N'a.'+@s),
        @FieldShow=REPLACE(@FieldShow,@s,N'a.'+@s),
        @Where1=STUFF(@Where1+N' AND a.'+@s+N'=b.'+@s,1,5,N''),    
        @Where2=CASE
            WHEN @WhereString='' THEN N'WHERE ('
            ELSE @WhereString+N' AND ('
            END+N'b.'+@s+N' IS NULL'+@Where2+N')'

    --执行查询
    EXEC(N'SELECT TOP '+@TopN
        +N' '+@FieldShow
        +N' FROM '+@tbname
        +N' a LEFT JOIN(SELECT TOP '+@TopN1
        +N' '+@FieldKey
        +N' FROM '+@tbname
        +N' a '+@WhereString
        +N' '+@FieldOrder
        +N')b ON '+@Where1
        +N' '+@Where2
        +N' '+@FieldOrder)
END



GO
SET QUOTED_IDENTIFIER OFF 
GO
SET ANSI_NULLS ON 
GO

很详细哦DbHelper.cs

    #region 执行分页存储过程,并输出总行数
    /// <summary>
    /// 执行分页存储过程,并输出总行数
    /// </summary>
    /// <param name="tableName">表名</param>
    /// <param name="iDName">主键ID</param>
    /// <param name="pageIndex">当前页</param>
    /// <param name="pageSize">每页显示数量</param>
    /// <param name="FieldShow">显示字段</param>
    /// <param name="orderby">排序字段</param>
    /// <param name="where">where条件</param>
    /// <param name="rowCount">返回总行数</param>
    /// <returns></returns>
    public DataTable ExecProPageList(string tableName, string iDName, int pageIndex, int pageSize, string FieldShow, string orderby, string where, out int rowCount)
    {
        rowCount = 0;
        SqlParameter[] parameters = {
                new SqlParameter("@tbname", SqlDbType.NVarChar,30),
                new SqlParameter("@FieldKey", SqlDbType.NVarChar,20),
                new SqlParameter("@PageCurrent", SqlDbType.Int,4),
                new SqlParameter("@PageSize ", SqlDbType.Int,4),
                new SqlParameter("@FieldShow", SqlDbType.NVarChar,255),
                new SqlParameter("@FieldOrder", SqlDbType.NVarChar,255),
                new SqlParameter("@WhereString", SqlDbType.NVarChar,255),
                new SqlParameter("@RecordCount", SqlDbType.Int,4)
           };
        parameters[0].Value = tableName;
        parameters[1].Value = iDName;
        parameters[2].Value = pageIndex;
        parameters[3].Value = pageSize;
        parameters[4].Value = FieldShow;
        parameters[5].Value = orderby;
        parameters[6].Value = where;
        parameters[7].Value = rowCount;
        parameters[7].Direction = ParameterDirection.Output;
        SqlCommand cmd = new SqlCommand();
        cmd.Connection = Connection;
        cmd.CommandText = "PROCE_PageView";// "GetPageDataOut";
        cmd.CommandType = CommandType.StoredProcedure;
        cmd.Parameters.AddRange(parameters);
        SqlDataAdapter da = new SqlDataAdapter(cmd);
        DataTable dt = new DataTable();
        da.Fill(dt);
        rowCount = Convert.ToInt32(cmd.Parameters["@RecordCount"].Value);
        return dt;
    }
    #endregion

3.页面调用

 DataTable dt = sqldb.ExecProPageList("t_translator", "name", PageNum, NumPerPage, "", "", Where1, out TotalRe);

where1条件时，最好判断一下是否有值。