学步园

'当单击菜单项命令“关于”时，弹了出消息框
Private Sub About_Click()
 '关于本程序的信息
 MsgBox "个人记事本 1.0 ", vbOKOnly, "关于"
End Sub

Private Sub All_Click()
 Rtb.SelStart = 0 '设置文本的起始点
 Rtb.SelLength = Len(Rtb.Text) '根据文本的全部字符数长度设置所选择的字符数
End Sub

Private Sub Copy_Click()
 Clipboard.Clear '清除剪贴板（Clipboard）的内容
 Clipboard.SetText Rtb.SelText '将所选择的文本放到剪贴板上
End Sub

Private Sub Cut_Click()
 Clipboard.Clear '清除剪贴板的内容
 Clipboard.SetText Rtb.SelText '将所选择的文本放到剪贴板上
 Rtb.SelText = "" '清除文本中的内容
End Sub

Private Sub Exit_Click()
 End
End Sub

Private Sub Find_Click()
 '用输入框来输入查询条件，并将输入内容赋值给查找变量Findstr
 Findstr = InputBox("请输入要查找的字、词：", "查找内容", Findstr)
 Rtb.Find Findstr '根据给定的字符串，使用方法Find来搜索文本
End Sub

Private Sub FindOn_Click()
 Rtb.SelStart = Rtb.SelStart + Rtb.SelLength + 1 '设置下一个搜索的开始为置
 '根据给定的字符串，搜索文本，并从指定的开始位置搜索的文本的末尾
 Rtb.Find Findstr, , Len(Rtb)
End Sub

Private Sub Font_Click()
 ComDia.Flags = 1 '打开标准对话框ComDia的Flags属性值
 ComDia.ShowFont '打开标准字体对话框
 Rtb.SelFontName = ComDia.FontName '根据在标准字体对话框中所选确定字体(字体类型、大小、粗斜)
 Rtb.SelFontSize = ComDia.FontSize
 Rtb.SelBold = ComDia.FontBold
 Rtb.SelItalic = ComDia.FontItalic
End Sub

Private Sub Color_Click()
 ComDia.ShowColor '打开标准颜色对话框
 Rtb.SelColor = ComDia.Color '根据在标准颜色对话框中所选确定颜色
End Sub

Private Sub New_Click()
 Rtb.Text = "" '清空文本框
 FileName = "新建个人记事本" '设置窗体的标题
 Me.Caption = FileName
End Sub

Private Sub Open_Click()
 '设置对话框的显示文件类型
 ComDia.Filter = "文本文档(*.txt)|*.txt|RTF文档(*.rtf)|*.rtf|所有文件(*.*)|*.*"
 ComDia.ShowOpen '显示 ComDia控件的"打开"对话框
 Rtb.Text = "" '清空文本框
 FileName = ComDia.FileName '将选择文件的文件名赋值给文件名称变量FileName
 Rtb.LoadFile FileName '加载一个文件名为FileName的文件
 Me.Caption = "个人记事本：" & FileName '设置窗体的标题
End Sub

Private Sub Paste_Click()
 Rtb.SelText = Clipboard.GetText '将剪贴板上的内容粘贴到文本框中
End Sub

Private Sub Save_Click()
 '设置对话框的保存文件类型
 ComDia.Filter = "文本文档(*.txt)|*.txt|RTF文档(*.rtf)|*.rtf|所有文件(*.*)|*.*"
 ComDia.ShowSave '显示 ComDia控件的"保存"对话框
 FileTypestr = ComDia.FileTitle '返回对话框保存文件的名称，并赋值给文件类型变量FileTypestr
 FiTypestr = LCase(Right(FileTypestr, 3)) '提取文件类型
 FileName = ComDia.FileName '返回保存的文件名

 '保存为纯文本文档
 If FiTypestr = "txt" Then
  Rtb.SaveFile FileName, rtfText
 End If
 '保存为RTF文档，RTF文档能保存字体等格式
 If FiTypestr = "rtf" Then
  Rtb.SaveFile FileName, rtfRTF
 End If

  '保存为所有文件
 If FiTypestr = "*.*" Then
  Rtb.SaveFile FileName
 End If

 Me.Caption = "个人记事本：" & FileName '设置窗体的标题
End Sub

'点击鼠标右键出现弹出菜单
Private Sub rtb_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
 If Button = 2 Then
  PopupMenu Edit '把编辑菜单显示为弹出菜单
 Else
  Exit Sub
 End If
End Sub

'当单击菜单命令“显示/隐藏工具栏”时，首先判断当前命令是否是选中状态
'如果是选中状态，则取消选中状态，隐藏工具栏；否则相反
Private Sub Show1_Click()
 If Show1.Checked = True Then
  Show1.Checked = False '将菜单命令Show1的Checked属性设为False，取消选中
  Toolbar1.Visible = False '将工具栏Toolbar1的Visible属性设为False，隐藏工具栏
 Else
  Show1.Checked = True
  Toolbar1.Visible = True
 End If
End Sub

'当工具栏上的按钮被按下时，执行Toolbar1_ButtonClick事件过程
'该过程判断哪一个工具按钮被按下，调用相应的事件过程来执行命令
Private Sub Toolbar1_ButtonClick(ByVal Button As MSComctlLib.Button)
 Select Case Button.Key
  Case "t1"
   New_Click '调用菜单命令New的Click()过程
  Case "t2"
   Open_Click
  Case "t3"
   Save_Click
  Case "t4"
   Copy_Click
  Case "t5"
   Cut_Click
  Case "t6"
   Paste_Click
 End Select
End Sub