学步园

getChildIndex( ) 与getChildAt( )方法用于获取项目在显示对象列表中的位置
讨论：

setChildIndex( )用于重置容器对象中子对象的显示顺序
它有两个参数,一个是被移动的子对象，一个被移动子对象新位置的索引值
注意这个所以值必须是有效的，不能为负数或者大于numchildren
下面的例子创建了3个不同颜色的圈，蓝色在最上边，setChildIndex( ) 方法被用于将蓝色圈置于其它连个圈的下边
即改变它在容器中索引值由2变为0，同时其它子对象的位置也发生对应的改变，红色圈的索引值变为1，绿色圈的索引值变为2
package {
  import flash.display.*;
  public class SetChildIndexExample extends Sprite {
    public function SetChildIndexExample(  ) {
      //在不同位置，创建三个不同颜色的圈
      var red:Shape = createCircle( 0xFF0000, 10 );
      red.x = 10;
      red.y = 20;
      var green:Shape = createCircle( 0x00FF00, 10 );
      green.x = 15;
      green.y = 25;
      var blue:Shape = createCircle( 0x0000FF, 10 );
      blue.x = 20;
      blue.y = 20;
      
      // 将三个圈加入显示对象列表，红色圈的索引值是0, 绿色为 1, 蓝色为 2
      addChild( red );
      addChild( green );
      addChild( blue );
      //移动蓝色圈，让其在另外两个圈的下边
      setChildIndex( blue, 0 );
    }
   
    //创建圈的函数
    public function createCircle( color:uint, radius:Number ):Shape {
      var shape:Shape = new Shape(  );
      shape.graphics.beginFill( color );
      shape.graphics.drawCircle( 0, 0, radius );
      shape.graphics.endFill(  );
      return shape;
    }
  }
}

另外就是假设如果你不知道红色圈的位置，但是也想让蓝色圈在红色圈的下边
你可以用

getChildIndex( ) 或getChildAt( )配合setChildIndex()来使用

例如：
setChildIndex(blue,getChildIndex(red));