学步园

package
{
 import com.adobe.utils.StringUtil;
 
 import flash.external.ExternalInterface;
 
 /**
  * 与javascript，工具
  */
 public class ASReadCookie
 {
  public function ASReadCookie()
  {
  }
  
  /**
   * 检测是否是IE
   */
  public static function isIE():Boolean
  {
   if(!ExternalInterface.available) return true ;
   var nam:String =  ExternalInterface.call('function getName(){return navigator.appName ;}') ;
   return nam.indexOf('Microsoft')!= -1 ;
  }
  
  /**
   * 检测是否是firefox
   */
  public static function isFirefox():Boolean
  {
   if(!ExternalInterface.available) return true ;
   var nam:String =  ExternalInterface.call('function getName(){return navigator.appName ;}') ;
   return nam.indexOf('Netscape')!= -1 ;
  }
  
  /**
   * get browser name
   */
  public static function getAppName():String
  {
   if(!ExternalInterface.available) return '' ;
   return ExternalInterface.call('function getName(){return navigator.appName ;}') ;
  }
  
  /**
   * get browser version
   */
  public static function getAppVersion():String
  {
   if(!ExternalInterface.available) return '' ;
   return ExternalInterface.call('function getName(){return navigator.appVersion ;}') ;
  }
  
  /**
   * get cookie
   * 组成一个数组（每个单元是一个键值对）
   */
  public static function getCookie():Array
  {
   if(!ExternalInterface.available) return [] ;
   var out:Array = [];
   var cookieStr:String = ExternalInterface.call( "function getCookie(){return document.cookie;}" )
   if(cookieStr == '' || cookieStr == null) return [];
   var cookieArr:Array = cookieStr.split(";");
   for(var i:int=0;i<cookieArr.length;i++)
   {
    var items:Array = String(cookieArr[i]).split('=');
    var obj:Object = ({key:StringUtil.trim(String(items[0])),value:StringUtil.trim(String(items[1]))});
    out.push(obj);
   }
   return out;
  }
  
  /**
   * javascript alert
   */
  public static function jsAlert(str:String):void
  {
   if(!ExternalInterface.available) return  ;
   ExternalInterface.call('function jsAlert(){alert("' + str + '") ;}') ;
  }
  
  /**
   * 打开网页
   */
  public static function openWindow(url:String,full:Boolean=false):void
  {
   if(!ExternalInterface.available) return  ;
   if(full)
   {
    ExternalInterface.call('function openWin(){window.open("' + url + '" , "win", "toolbar=no, menubar=no,scrollbars=no,resizable=no,location=no,status=no" ) ;}') ;
   }
   else
   {
    ExternalInterface.call('function openWin(){window.open("' + url + '") ;}') ;
   }
   
  }
  
  /**
   * 关闭网页
   */
  public static function closeWindow():void
  {
   if(!ExternalInterface.available) return  ;
   ExternalInterface.call('function jsAlert(){ window.close() }') ;
  }
  
  /**
   * 获取url
   */
  public static function getURL():String
  {
   if(!ExternalInterface.available) return '' ;
   return ExternalInterface.call('function getURL(){return location.href ;}') ;
  }
  
  /**
   * 获取参数
   */
  public static function getParam():Array
  {
   if(!ExternalInterface.available) return [] ;
   var url:String = getURL();
   if(url.indexOf('?')==-1) return [];
   var out:Array = [];
   var paramStr:String = url.split('?')[1];
   var paramArr:Array = paramStr.split('&');
   for(var i:int=0;i<paramArr.length;i++)
   {
    var tempArr:Array = String(paramArr[i]).split('=');
    out.push({key:tempArr[0],value:tempArr[1]})
   }
   return out;
  }
  
  
  
  
  
  
  
  
  
  
  
  
  
 }
}

code : http://www.sandy1219.com/code/ASReadCookie.rar