学步园

首先，需要定义utl_file_dir 
查看show   parameter   utl_file_dir
如果没有定义执行
alter   system   set   UTL_FILE_DIR='/tmp'   scope=spfile;  
UTL_FILE_DIR可以根据情况指定，只是修改了SPFILE，但是数据库中还没有生效。  
 
  SQL>shutdown  
  关闭数据库  
  SQL>startup  
  打开数据库  
  SQL>   show   parameter   utl_file_dir

SQL> show parameter utl
NAME                                 TYPE        VALUE
------------------------------------ ----------- ------------------------------
utl_file_dir                         string      /oracle/script, /tmp
 
这里系统以前就指定了/tmp作为目录（这个目录虽然足够很大，不过大文件尽量不要放在这里，
比较危险），然后需要创建一个directory，方法很简单：
 
CREATE OR REPLACE DIRECTORY UTLDIR AS '/tmp';
 
然后需要在查询用户下建个function了，这个function是解决这个问题的核心：
CREATE function dump_csv( p_query     in varchar2,
                                      p_separator in varchar2
                                                    default ',',
                                      p_dir       in varchar2 ,
                                      p_filename  in varchar2 )
return number
AUTHID CURRENT_USER
is
    l_output        utl_file.file_type;
    l_theCursor     integer default dbms_sql.open_cursor;
    l_columnValue   varchar2(2000);
    l_status        integer;
    l_colCnt        number default 0;
    l_separator     varchar2(10) default '';
    l_cnt           number default 0;
begin
    l_output := utl_file.fopen( p_dir, p_filename, 'w' );
    dbms_sql.parse(  l_theCursor,  p_query, dbms_sql.native );
    for i in 1 .. 255 loop
        begin
            dbms_sql.define_column( l_theCursor, i,
                                    l_columnValue, 2000 );
            l_colCnt := i;
        exception
            when others then
                if ( sqlcode = -1007 ) then exit;
                else
                    raise;
                end if;
        end;
    end loop;
    dbms_sql.define_column( l_theCursor, 1, l_columnValue,
                            2000 );
    l_status := dbms_sql.execute(l_theCursor);
    loop
        exit when ( dbms_sql.fetch_rows(l_theCursor) <= 0 );
        l_separator := '';
        for i in 1 .. l_colCnt loop
            dbms_sql.column_value( l_theCursor, i,
                                   l_columnValue );
            utl_file.put( l_output, l_separator ||
                                    l_columnValue );
            l_separator := p_separator;
        end loop;
        utl_file.put( l_output, l_separator);
        utl_file.new_line( l_output );
        l_cnt := l_cnt+1;
    end loop;
    dbms_sql.close_cursor(l_theCursor);
    utl_file.fclose( l_output );
    return l_cnt;
end dump_csv;
/
之后，只需要使用命令
SQL> select dump_csv('select * from dn2int','|','/tmp','dn2int.unl') from dual;
DUMP_CSV('SELECT*FROMTEST',',','/tmp','EMP.CSV')
-------------------------------------------------------
                                                      3
查看/tmp/emp.csv文件
1,1,
2,2,
4,4,