学步园

转载地址：http://blog.chinaunix.net/uid-26435987-id-3075221.html
启动代码主要是在主程序运行之前初始化系统硬件及软件的运行环境，它的主要功能包括以下的几个方面：

1、建立中断向量表

2、初始化系统堆栈

3、应用程序执行环境初始化

4、跳转至主函数

第一部分

 GET option.inc           ；option.inc文件包含了开发板的配置信息—堆栈、时钟等

 GET memcfg.inc           ；存储控制文件

 GET 2440addr.inc         ；寄存器地址地址定义

注意：   汇编不能使用include包含头文件，所有用Get，功能：引进一个被编译过的文件

        汇编也不认识*.h 文件，所有只能用*.inc

第二部分

;EQU为程序中的常量、标号等定义一个等效的字符名称，相当于C语言中的define
;定义SDRAM工作在Refresh模式，SDRAM有两种刷新方式：autorefresh和selfrefresh，前者是在其使用过程当中每隔一段时间发出刷新指令，SDRAM刷新一行，selfrefresh是在省电模式时使用。标示：REFRESH寄存器[22]bit : 0- auto refresh; 1 - self refresh
BIT_SELFREFRESH   EQU   (1<<22)   ;用于节电模式中，SDRAM自刷新标志位

第三部分（简单略过）

;系统的工作模式设定,共七种工作模式
USERMODE    EQU      0x10
FIQMODE      EQU      0x11
IRQMODE      EQU      0x12
SVCMODE      EQU      0x13
ABORTMODE   EQU      0x17
UNDEFMODE   EQU      0x1b
MODEMASK    EQU      0x1f
NOINT         EQU       0xc0

;设置6种工作模式的堆栈的起始地址

;在option.inc中定义了_STACK_BASEADDRESS  EQU  0x33ff8000 
UserStack EQU (_STACK_BASEADDRESS-0x3800)   ;0x33ff4800 ~
SVCStack EQU (_STACK_BASEADDRESS-0x2800)   ;0x33ff5800 ~
UndefStack EQU (_STACK_BASEADDRESS-0x2400)  ;0x33ff5c00 ~
AbortStack EQU (_STACK_BASEADDRESS-0x2000)  ;0x33ff6000 ~
IRQStack EQU (_STACK_BASEADDRESS-0x1000)   ;0x33ff7000 ~
FIQStack EQU (_STACK_BASEADDRESS-0x0)      ;0x33ff8000 ~

第四部分：

;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.

; 判断是否THUMB指令

;   [ 代表IF，| 指的是ELSE，] 相当于ENDIF

       

GBLL    THUMBCODE ;定义一个全局的逻辑变量，变量名为THUMBCODE

       [ {CONFIG} = 16   ;如果是CONFIG}= 16，表明现在处于thumb状态

THUMBCODE  SETL  {TRUE} ;将该变量赋值为真，表示告诉系统当前想用Thumb，但实际启动时不行，只能从ARM启动后再跳转到thumb

           CODE32  ;启动时强制使用32 位ARM编译模式 

             |

THUMBCODE SETL  {FALSE}；如果系统要求是ARM 指令，则直接设置THUMBCODE 

                              为false ，说明当前的是32 位编译模式 

        ]

             

  ;宏定义MOV_PC_LR，作用：子程序返回 

   MACRO      ;宏定义 

   MOV_PC_LR 

   [ THUMBCODE      ;目标地址是THUMB指令 

   bx lr            ;在ARM模式中，要用BX指令跳转到THUMB指令，并转换模式

   |  

   mov pc,lr   ;如果目标地址是ARM指令，则直接把函数返回地址给PC

   ] 

MEND ;宏定义结束 

  ;宏定义MOVEQ_PC_LR，作用：带相等条件判断的子程序返回 。与宏定义 

  ;带条件的函数返回，与MOV_PC_LR类似  

  MACRO 

  MOVEQ_PC_LR 

  [ THUMBCODE 

bxeq lr 

| 

    moveq pc,lr 

  ] 

MEND ;宏定义结束 

接上篇，代码如下：

IMPORT  |Image$$RO$$Base|    ; Base of ROM code; ROM code(也就是代码)的开始地址 

IMPORT  |Image$$RO$$Limit|     ; ROM code的结束地址(=ROM data的开始地址) 

IMPORT  |Image$$RW$$Base|     ; Base of RAM to initialise; RAM 的起始地址 

IMPORT  |Image$$ZI$$Base|       ; Base and limit of area       0初始化的起始地址 

IMPORT  |Image$$ZI$$Limit|       ; to zero initialise               0初始化的结束地址 

; 在这里用IMPORT伪指令(和c语言的extren关键字一样)引入|Image$$RO$$Base|, 

Image$$RO$$Limit|,|Image$$RW$$Base|, |Image$$ZI$$Base|,|Image$$ZI$$Limit|等比较古怪的变量是编译器生成的。 

;其中RO, RW, ZI这三个段都保存在Flash中（加载时），但RW，ZI在Flash中的地址肯定不是程序运行时变量所存储的位置，因此我们的程序在初始化时应该把Flash中的RW，ZI拷贝到RAM的对应位置。这些变量是通过ADS的工程设置里面设定的RO Base和RW Base设定的, 最终由编译脚本和连接程序导入程序. 实际上RW，ZI在Flash中的位置就紧接着RO存储。我们知道Image$$RO$$Base，Image$$RO$$Limit，那么Image$$RO$$Limit就是RW （ROM data）的开始。 

IMPORT   MMU_SetAsyncBusMode 

IMPORT   MMU_SetFastBusMode 

;在这里用IMPORT伪指令(和c语言的extren一样)引入外部变量MMU的快速总线模式和异步总线模式两个变量. 

IMPORT  Main     ; The main entry of mon program 

;在这里引入一些在其它文件中实现在函数,包括为我们所熟知的main函数

 IMPORT  RdNF2SDRAM   ; Copy Image from Nand Flash to SDRAM

;在这里引入一些在其他文件中实现的函数，包括复制代码到SDRAM

注意最后一句我想强调的是：

NAND启动时，当里面程序小于4K时，不用写什么搬移程序，启动后S3C2440会通过硬件机制将NAND的小于4K的内容，拷贝到其零地址处自带的BootSRAM，然后再运行里面的程序（从0地址处）   

                        当里面程序大于4K时，此时系统只将NAND的前4K内容硬件机制方式的搬移到BootSRAM

中，还有部分程序保存在NAND中，而NAND是无法运行程序的，需要将所有程序搬移到SDRAM并在其中运行，所以程序的启动代码要包含这块有关程序拷贝的代码，并在所有程序完成拷贝后在SDRAM中运行。更简单的说，在大于4K条件下，NAND有两个过程，一过程是将NAND前4K内容搬移到BootSRAM中，目的是使系统能够启动（硬件机制，无须程序员干预）；二过程是使得程序所有程序搬运到SDRAM中，目的是使程序在SDRAM中运行（需要程序员编程实现）。

NOR启动时，没有额外要考虑的问题，因为NOR特点是芯片内执行，系统上电或复位，0地址处的启动代码就会被执行

;中断向量表一般位于启动代码的开始部分，它是用户程序与启动代码之间以及启动代码的各部分之间联系的纽带。它由一个一个的跳转函数组成，它就象一个普通的散转函数，只不过散转的过程中有硬件机制参与，当系统发生异常时，ARM 处理器会通过硬件机制强制将PC 指针指向中断向量表中对应的异常跳转函数存储的地址，然后程序会跳转到相应的中断服务程序去执行。(别忘了前篇有个复位b
ResetHandler ）

b     HandlerUndef  ;handler for Undefined mode 未定义异常，遇到无法识别的指令时0x04

b     HandlerSWI    ;handler for SWI interrupt，软中断异常0x08

b     HandlerPabort  ;handler for PAbort指令预取错误时进入0x0c

b     HandlerDabort  ;handler for DAbort数据访问不能完成时进入0x10

b     .                      ;reserved, 保留 0x14

b     HandlerIRQ      ;handler for IRQ interrupt发生IRQ 中断时进入0x18

b     HandlerFIQ      ;handler for FIQ interrupt发生FIQ 中断时进入0x1c

b   EnterPWDN   ; Must be @0x20.

这个b   EnterPWDN没太见过，然后点击查看到在2440lib.c头文件中可以见到这样的宏声明：
#define    EnterPWDN(clkcon)   ((void (*)(int))0x20)(clkcon) 

不难看出，当我们编程调用EnterPWDN(clkcon)函数的时候，编译器在编译前首先把EnterPWDN(clkcon)转换为((void
(*)(int))0x20)(clkcon)语句。现在分析这个语句，对于这个语句，我们先将之分解成3个部分来看：
 如下：  1:(void (*)(int)        2:0x20        3:(clkcon)

其中(clkcon)是函数的参数，对照着看就知道了；0x20是要转换的函数的入口地址；着重看(void (*)(int)，这部分作为一个整体，描述了转换后的函数的类型，即无返回值，带一个整形参数。而中间那个“(*)”，表示是要转换成一个函数，类比一下就像我们平常用的强制类型转换一样，（int）temp，只不过这里是将一个数转换为另一类型，而咱们刚说的是将一个地址转换为一个函数。

;通过设置CP15 的C1 的位7，设置存储格式为Bigendian，三种总线方式ChangeBigEndian ，下面是改变大小端的程序,这里采用直接定义机器码的方式

  [ ENTRY_BUS_WIDTH=32 

      DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0 

      DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80;           //Big-endian 

      DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0 

;对存储器控制寄存器操作，指定内存模式为Big-endian 

;因为刚开始CPU 都是按照32位总线的指令格式运行的，如果采用其他的话，CPU识别不了，必须转化，但当系统初始化好以后，CPU能自动识别。

  ] 

  [ ENTRY_BUS_WIDTH=16 

      DCD 0x0f10ee11 

      DCD 0x0080e380 

      DCD 0x0f10ee01 

;因为采用Big-endian 模式，采用16 位总线时，物理地址的高位和数据的低位对应，所以指令的机器码也相应的高低对调 

  ] 

  [ ENTRY_BUS_WIDTH=8 

      DCD 0x100f11ee 

      DCD 0x800080e3 

      DCD 0x100f01ee 

     ] 

  DCD 0xffffffff   ;swinv 0xffffff is similar with NOP and run well in both endian mode. 

  DCD 0xffffffff 

  DCD 0xffffffff 

  DCD 0xffffffff 

  DCD 0xffffffff 

  b  ResetHandler 

;堆栈初始化的顺序决定系统最后运行在哪种处理器模式，最后初始化哪种模式的堆栈，系统就运行在哪种模式。

InitStacks

 mrs r0,cpsr

 bic r0,r0,#MODEMASK         ;屏蔽低5位
 orr r1,r0,#UNDEFMODE|NOINT  ;屏蔽6、7位和选择未定义模式
 msr cpsr_cxsf,r1            ;UndefMode
 ldr sp,=UndefStack          ;UndefStack=0x33FF_5C00

 orr r1,r0,#ABORTMODE|NOINT

 msr cpsr_cxsf,r1             ;AbortMode
 ldr sp,=AbortStack           ; AbortStack=0x33FF_6000

 orr r1,r0,#IRQMODE|NOINT

 msr cpsr_cxsf,r1             ;IRQMode
 ldr sp,=IRQStack             ;IRQStack=0x33FF_7000

 orr r1,r0,#FIQMODE|NOINT

 msr cpsr_cxsf,r1             ;FIQMode
 ldr sp,=FIQStack             ;FIQStack=0x33FF_8000

 bic r0,r0,#MODEMASK|NOINT

 orr r1,r0,#SVCMODE

 msr cpsr_cxsf,r1             ;SVCMode,管理模式
 ldr sp,=SVCStack             ;SVCStack=0x33FF_5800

 mov pc,lr

[ {TRUE}

 |

ReadNandID

 mov      r7,#NFCONF

 ldr      r0,[r7,#4]  ;NFChipEn();

 bic      r0,r0,#2

 str      r0,[r7,#4]

 mov      r0,#0x90  ;WrNFCmd(RdIDCMD);

 strb     r0,[r7,#8]

 mov      r4,#0   ;WrNFAddr(0);

 strb     r4,[r7,#0xc]

1       ;while(NFIsBusy());

 ldr      r0,[r7,#0x20]

 tst      r0,#1

 beq      %B1

 ldrb     r0,[r7,#0x10] ;id  = RdNFDat()<<8;

 mov      r0,r0,lsl #8

 ldrb     r1,[r7,#0x10] ;id |= RdNFDat();

 orr      r5,r1,r0

 ldr      r0,[r7,#4]  ;NFChipDs();

 orr      r0,r0,#2

 str      r0,[r7,#4]

 mov   pc,lr 

 

ReadNandStatus

 mov   r7,#NFCONF

 ldr      r0,[r7,#4]  ;NFChipEn();

 bic      r0,r0,#2

 str      r0,[r7,#4]

 mov      r0,#0x70  ;WrNFCmd(QUERYCMD);

 strb     r0,[r7,#8] 

 ldrb     r1,[r7,#0x10] ;r1 = RdNFDat();

 ldr      r0,[r7,#4]  ;NFChipDs();

 orr      r0,r0,#2

 str      r0,[r7,#4]

 mov   pc,lr

WaitNandBusy

 mov      r0,#0x70  ;WrNFCmd(QUERYCMD);

 mov      r1,#NFCONF

 strb     r0,[r1,#8]

1       ;while(!(RdNFDat()&0x40)); 

 ldrb     r0,[r1,#0x10]

 tst      r0,#0x40

 beq   %B1

 mov      r0,#0   ;WrNFCmd(READCMD0);

 strb     r0,[r1,#8]

 mov      pc,lr

;============================================================================

CheckBadBlk

 mov  r7, lr

 mov  r5, #NFCONF

 

 bic      r0,r0,#0x1f ;addr &= ~0x1f;

 ldr      r1,[r5,#4]  ;NFChipEn()

 bic      r1,r1,#2

 str      r1,[r5,#4]

 mov      r1,#0x50  ;WrNFCmd(READCMD2)

 strb     r1,[r5,#8]

 mov      r1, #5;6  ;6->5

 strb     r1,[r5,#0xc] ;WrNFAddr(5);(6) 6->5

 strb     r0,[r5,#0xc] ;WrNFAddr(addr)

 mov      r1,r0,lsr #8 ;WrNFAddr(addr>>8)

 strb     r1,[r5,#0xc]

 cmp      r6,#0   ;if(NandAddr)  

 movne    r0,r0,lsr #16 ;WrNFAddr(addr>>16)

 strneb   r0,[r5,#0xc]

 

; bl  WaitNandBusy ;WaitNFBusy()

 ;do not use WaitNandBusy, after WaitNandBusy will read part A!

 mov r0, #100

1

 subs r0, r0, #1

 bne %B1

2

 ldr r0, [r5, #0x20]

 tst r0, #1

 beq %B2 

 ldrb r0, [r5,#0x10] ;RdNFDat()

 sub  r0, r0, #0xff

 

 mov      r1,#0   ;WrNFCmd(READCMD0)

 strb     r1,[r5,#8]

 

 ldr      r1,[r5,#4]  ;NFChipDs()

 orr      r1,r1,#2

 str      r1,[r5,#4]

 

 mov  pc, r7

 

ReadNandPage

 mov   r7,lr

 mov      r4,r1

 mov      r5,#NFCONF

 ldr      r1,[r5,#4]  ;NFChipEn()

 bic      r1,r1,#2

 str      r1,[r5,#4] 

 mov      r1,#0   ;WrNFCmd(READCMD0)

 strb     r1,[r5,#8] 

 strb     r1,[r5,#0xc] ;WrNFAddr(0)

 strb     r0,[r5,#0xc] ;WrNFAddr(addr)

 mov      r1,r0,lsr #8 ;WrNFAddr(addr>>8)

 strb     r1,[r5,#0xc] 

 cmp      r6,#0   ;if(NandAddr)  

 movne    r0,r0,lsr #16 ;WrNFAddr(addr>>16)

 strneb   r0,[r5,#0xc]

 

 ldr      r0,[r5,#4]  ;InitEcc()

 orr      r0,r0,#0x10

 str      r0,[r5,#4]

 

 bl       WaitNandBusy ;WaitNFBusy()

 

 mov      r0,#0   ;for(i=0; i<512; i++)

1

 ldrb     r1,[r5,#0x10] ;buf[i] = RdNFDat()

 strb     r1,[r4,r0]

 add      r0,r0,#1

 bic      r0,r0,#0x10000

 cmp      r0,#0x200

 bcc      %B1

 

 ldr      r0,[r5,#4]  ;NFChipDs()

 orr      r0,r0,#2

 str      r0,[r5,#4]

  

 mov   pc,r7

 ]

;===================================================================================

 LTORG

;GCS0->SST39VF1601

;GCS1->16c550

;GCS2->IDE

;GCS3->CS8900

;GCS4->DM9000

;GCS5->CF Card

;GCS6->SDRAM

;GCS7->unused

SMRDATA DATA  ;SMRDATA是段名，DATA是属性（定义为数据段）

;DCD指令用于分配一片连续的字存储单元并用伪指令中指定的表达式初始化
 DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))

 DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))   ;GCS0
 DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))   ;GCS1
 DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))   ;GCS2
 DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))   ;GCS3
 DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))   ;GCS4
 DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))   ;GCS5
 DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6
 DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7
 DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Tsrc<<18)+(Tchr<<16)+REFCNT)

 DCD 0x32     ;SCLK power saving mode, BANKSIZE 128M/128M

 DCD 0x30     ;MRSR6 CL=3clk
 DCD 0x30     ;MRSR7 CL=3clk
 

BaseOfROM DCD |Image$$RO$$Base|

TopOfROM DCD |Image$$RO$$Limit|

BaseOfBSS DCD |Image$$RW$$Base|

BaseOfZero DCD |Image$$ZI$$Base|

EndOfBSS DCD |Image$$ZI$$Limit|

  ALIGN      ;LIGN 伪指令通过添加补丁字节使当前位置满足一定的对齐方式. 

;void EnterPWDN(int CLKCON);

EnterPWDN

    mov r2,r0               ;r2=rCLKCON 保存原始数据 0x4c00000c 使能各模块的时钟输入

    tst r0,#0x8              ;测试bit[3] SLEEP mode? 1=>sleep

    bne ENTER_SLEEP          ;C=0,即TST结果非0，bit[3]=1

;//进入PWDN后如果不是sleep则进入stop

ENTER_STOP   ;//进入Stop mode

       ldr r0,=REFRESH   ;0x48000024   DRAM/SDRAM refresh config

       ldr r3,[r0]              ;r3=rREFRESH

       mov r1, r3

       orr r1, r1, #BIT_SELFREFRESH  ;BIT_SELFREFRESH EQU (1<<22) ;SDRAM自刷新标志位

       str r1, [r0]             ;Enable SDRAM self-refresh

      mov r1,#16                   ;wait until self-refresh is issued(完成)not be needed.

0     subs r1,r1,#1

       bne %B0

 ;//wait 16 fclks for self-refresh

       ldr r0,=CLKCON          ;enter STOP mode.

       str r2,[r0]

 

       mov r1,#32

0     subs r1,r1,#1   ;1) wait until the STOP mode is in effect.

       bne %B0        ;2) Or wait here until the CPU&Peripherals(外设) will be turned-off

                     ; Entering SLEEP mode, only the reset by wake-up is available.

 

       ldr r0,=REFRESH ;exit from SDRAM self refresh mode.

       str r3,[r0]

 

       MOV_PC_LR    ;back to main process

ENTER_SLEEP

       ldr r0,=REFRESH

       ldr r1,[r0]              ;r1=rREFRESH

       orr r1, r1, #BIT_SELFREFRESH

       str r1, [r0]             ;Enable SDRAM self-refresh

 

       mov r1,#16                   ;Wait until self-refresh is issued,which may not be needed.

0     subs r1,r1,#1

       bne %B0

 

       ldr   r1,=MISCCR

       ldr   r0,[r1]

       orr   r0,r0,#(7<<17)  ;Set SCLK0=0, SCLK1=0, SCKE=0.

       str    r0,[r1]

 

       ldr r0,=CLKCON          ; Enter sleep mode

       str r2,[r0]

 

       b .                 ;CPU will die here.

 

 WAKEUP_SLEEP;从睡眠状态醒过来

       ;Release SCLKn after wake-up from the SLEEP mode.

       ldr   r1,=MISCCR

       ldr   r0,[r1]

       bic   r0,r0,#(7<<17)  ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.

       str    r0,[r1]

 

       ;Set memory control registers

      ldr   r0,=SMRDATA      ;be careful!

       ldr   r1,=BWSCON       ;BWSCON Address

       add  r2, r0, #52      ;End address of SMRDATA

0

       ldr   r3, [r0], #4

       str    r3, [r1], #4

       cmp r2, r0

       bne  %B0

 

       mov r1,#256

0     subs r1,r1,#1   ;1) wait until the SelfRefresh is released.

       bne %B0

 

       ldr r1,=GSTATUS3       ;GSTATUS3 has the start address just after SLEEP wake-up

       ldr r0,[r1]

 

       mov pc,r0

      

;=====================================================================

; Clock division test

; Assemble code, because VSYNC time is very short

;=====================================================================

       EXPORT CLKDIV124

       EXPORT CLKDIV144

      

CLKDIV124

      

       ldr     r0, = CLKDIVN

       ldr     r1, = 0x3         ; 0x3 = 1:2:4

       str     r1, [r0]

;      wait until clock is stable

       nop

       nop

       nop

       nop

       nop

 

       ldr     r0, = REFRESH

       ldr     r1, [r0]

       bic          r1, r1, #0xff

       bic          r1, r1, #(0x7<<8)

       orr          r1, r1, #0x470 ; REFCNT135

       str     r1, [r0]

       nop

       nop

       nop

       nop

       nop

       mov     pc, lr

 

CLKDIV144

       ldr     r0, = CLKDIVN

       ldr     r1, = 0x4         ; 0x4 = 1:4:4

       str     r1, [r0]

;      wait until clock is stable

       nop

       nop

       nop

       nop

       nop

 

       ldr     r0, = REFRESH

       ldr     r1, [r0]

       bic          r1, r1, #0xff

       bic          r1, r1, #(0x7<<8)

       orr          r1, r1, #0x630 ; REFCNT675 - 1520

       str     r1, [r0]

       nop

       nop

       nop

       nop

       nop

       mov     pc, lr

 

       ALIGN;按照一定的规则对齐，^符号相当于伪指令MAP，用于定义一个结构化的内存表的首地址

 

       AREA RamData, DATA, READWRITE

;

        ^  _ISR_STARTADDRESS              ; _ISR_STARTADDRESS=0x33FF_FF00

HandleReset   #   4;符号^ 相当于伪指令MAP，用于定义一个结构化的内存表的首地址

HandleUndef  #   4

HandleSWI    #   4

HandlePabort    #   4

HandleDabort    #   4

HandleReserved  #   4

HandleIRQ            #   4

HandleFIQ            #   4

 

;Do not use the label 'IntVectorTable',

;The value of IntVectorTable is different with the address you think it may be.

;IntVectorTable

;@0x33FF_FF20

HandleEINT0        #   4

HandleEINT1        #   4

HandleEINT2        #   4

HandleEINT3        #   4

HandleEINT4_7     #   4

HandleEINT8_23   #   4

HandleCAM          #   4            ; Added for 2440.

HandleBATFLT      #   4

HandleTICK          #   4

HandleWDT          #   4

HandleTIMER0     #   4

HandleTIMER1     #   4

HandleTIMER2     #   4

HandleTIMER3     #   4

HandleTIMER4     #   4

HandleUART2      #   4

;@0x33FF_FF60

HandleLCD           #   4

HandleDMA0        #   4

HandleDMA1        #   4

HandleDMA2        #   4

HandleDMA3        #   4

HandleMMC          #   4

HandleSPI0           #   4

HandleUART1              #   4

HandleNFCON             #   4            ; Added for 2440.

HandleUSBD         #   4

HandleUSBH         #   4

HandleIIC             #   4

HandleUART0       #   4

HandleSPI1          #   4

HandleRTC           #   4

HandleADC          #   4

;@0x33FF_FFA0

       END